blob: 7f26d511732b7f303eb1feb49f4487325a4cc2f7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# $Id: PKGBUILD 79610 2012-11-08 22:16:13Z lfleischer $
# Maintainer: Lukas Fleischer <archlinux@cryptocrack.de>
# Contributor: Vesa Kaihlavirta <vesa@archlinux.org>
# Contributor: Sarah Hay <sarahhay@mb.sympatico.ca>
# Contributor: Tom Burdick <thomas.burdick@wrightwoodtech.com>
# Contributor: Ricardo Catalinas Jiménez <jimenezrick@gmail.com>
pkgname=erlang
pkgver=R15B02
pkgrel=1
pkgdesc='A general-purpose concurrent functional programming language developed by Ericsson'
arch=(i686 x86_64)
url='http://www.erlang.org'
license=('custom')
depends=('ncurses' 'glibc')
makedepends=('java-environment' 'perl' 'openssl' 'wxgtk' 'unixodbc' 'mesa')
optdepends=('wxgtk: for wx support'
'mesa: for wx support'
'unixodbc: for database support'
'java-environment: for Java support')
source=("http://www.erlang.org/download/otp_src_$pkgver.tar.gz"
"http://www.erlang.org/download/otp_doc_man_$pkgver.tar.gz")
md5sums=('ccbe5e032a2afe2390de8913bfe737a1'
'974020ba533242fca759a7f5eaf628e5')
build() {
cd "$srcdir/otp_src_$pkgver"
./configure --prefix=/usr --enable-smp-support
make
}
package() {
cd "$srcdir/otp_src_$pkgver"
make DESTDIR="$pkgdir" install
# Install documentation
install -d "$pkgdir/usr/share/doc/erlang"
install -m0644 "$srcdir/otp_src_$pkgver"/README.md "$srcdir"/{README,COPYRIGHT} \
"$pkgdir/usr/share/doc/erlang"
# Install compressed man pages
for page in "$srcdir/man/man?/*"; do
gzip $page
done
cp -r "$srcdir/man" "$pkgdir/usr/lib/erlang"
# Install license
install -Dm0644 "$srcdir/otp_src_$pkgver/EPLICENCE" \
"$pkgdir/usr/share/licenses/$pkgname/EPLICENCE"
}
|