blob: ce845a9966a81167dbf8114ed38736fb3cdf397b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# $Id: PKGBUILD 81307 2012-12-17 09:59:36Z arodseth $
# Maintainer: Lukas Fleischer <archlinux@cryptocrack.de>
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Vesa Kaihlavirta <vesa@archlinux.org>
# Contributor: Sarah Hay <sarahhay@mb.sympatico.ca>
# Contributor: Tom Burdick <thomas.burdick@wrightwoodtech.com>
# Contributor: Ricardo Catalinas Jiménez <jimenezrick@gmail.com>
pkgname=erlang
pkgver=R15B03_1
pkgrel=1
pkgdesc='General-purpose concurrent functional programming language developed by Ericsson'
arch=(i686 x86_64 mips64el)
url='http://www.erlang.org'
license=('custom')
depends=('ncurses' 'glu' 'wxgtk' 'openssl')
makedepends=('perl' 'mesa' 'lksctp-tools')
optdepends=('unixodbc: for database support'
'lksctp-tools: for SCTP support')
source=("http://www.erlang.org/download/otp_src_${pkgver/_/-}.tar.gz"
"http://www.erlang.org/download/otp_doc_man_${pkgver/_/-}.tar.gz")
sha256sums=('4bccac86dd76aec050252e44276a0283a0df9218e6470cf042a9b9f9dfc9476c'
'07980d8014c7cf8194b7078c137353f5083992add4663ced3dcba2ff91f228d8')
build() {
cd "$srcdir/otp_src_${pkgver/_1/}"
msg2 'Configuring...'
./configure --prefix=/usr --enable-smp-support
msg2 'Compiling...'
make
}
package() {
cd "$srcdir/otp_src_${pkgver/_1/}"
make DESTDIR="$pkgdir" install
# Install documentation
install -d "$pkgdir/usr/share/doc/erlang"
install -m0644 "$srcdir/otp_src_${pkgver/_1/}/README.md" \
"$srcdir"/{README,COPYRIGHT} \
"$pkgdir/usr/share/doc/erlang"
# Install compressed man pages
for page in "$srcdir/man/man?/*"; do gzip $page; done
cp -r "$srcdir/man" "$pkgdir/usr/lib/erlang"
# Install license
install -Dm0644 "$srcdir/otp_src_${pkgver/_1/}/EPLICENCE" \
"$pkgdir/usr/share/licenses/$pkgname/EPLICENCE"
}
# vim:set ts=2 sw=2 et:
|
