blob: 199c369317c677d4515a4d54926f262d3addf216 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
# $Id: PKGBUILD 83238 2013-01-28 15:29:15Z ttoepper $
# Contributor: Giorgio Lando <lando at imap dot cc>
# Contributor: Sergej Pupykin
# Contributor: Thomas Bächler
# Maintainer: Thorsten Töpper <atsutane-tu@freethoughts.de>
pkgname=fcron
pkgver=3.1.1
pkgrel=1
pkgdesc='Feature-rich cron implementation'
arch=(i686 x86_64)
url="http://fcron.free.fr"
license=('GPL')
depends=('pam')
makedepends=('smtp-server')
optdepends=('smtp-server: to receive mails from cron jobs')
provides=('cron')
conflicts=('dcron')
backup=(etc/fcron/fcron.conf etc/fcron/fcron.allow etc/fcron/fcron.deny \
var/spool/fcron/systab var/spool/fcron/systab.orig)
options=('emptydirs' '!makeflags')
source=(http://fcron.free.fr/archives/$pkgname-$pkgver.src.tar.gz fcron.rc \
systab systab.orig run-cron fcron.service)
md5sums=('230b91f308e6012957a3a71a94f03838'
'e0c3f0bdc3c98fbbe46eff19001c18f2'
'938722c6654ef7b07f4aa10001905ba1'
'bfb7daa22ebe22b9917e455c1ca4a382'
'5ff0cdcb9ec99778938ac6ef26800327'
'973e440ba6d9ea5aa00b45377140fae4')
build() {
cd "$srcdir/$pkgname-$pkgver"
./configure --prefix=/usr \
--sysconfdir=/etc/fcron \
--with-answer-all=no \
--with-boot-install=no \
--with-username=root \
--with-groupname=root \
--datarootdir=/usr/share \
--datadir=/usr/share \
--with-docdir=/usr/share/doc \
--localstatedir=/var \
--with-systemdsystemunitdir=/usr/lib/systemd/system \
--with-piddir=/run \
--with-editor=/usr/bin/vi \
--with-sendmail=/usr/sbin/sendmail
make
# Temporary bugfix make install expects the file in the files directory.
cp script/fcron.init.systemd files
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir/" install
install -D -m755 "$srcdir/fcron.rc" "$pkgdir/etc/rc.d/fcron"
install -D -m644 "$srcdir/$pkgname-$pkgver/files/fcron.pam" "$pkgdir/etc/pam.d/fcron"
install -D -m644 "$srcdir/$pkgname-$pkgver/files/fcrontab.pam" "$pkgdir/etc/pam.d/fcrontab"
# Install default fcrontab so that fcron can completely replace dcron
install -D -m600 "$srcdir/systab" "$pkgdir/var/spool/fcron/systab"
# In order to preserve the systab crontab in any case it is better to have
# it in non-binary form too
install -D -m600 "$srcdir/systab.orig" "$pkgdir/var/spool/fcron/systab.orig"
# Add cron.* directories
install -d -m755 "$pkgdir/etc/cron.daily"
install -d -m755 "$pkgdir/etc/cron.hourly"
install -d -m755 "$pkgdir/etc/cron.monthly"
install -d -m755 "$pkgdir/etc/cron.weekly"
# Install run-cron script to make fcron run without dcron
install -D -m755 "$srcdir/run-cron" "$pkgdir/usr/sbin/run-cron"
# Install systemd service
#install -D -m644 "$srcdir/fcron.service" \
# "$pkgdir/usr/lib/systemd/system/fcron.service"
# avoid conflict with filesystem>=2012.06
rmdir "$pkgdir/var/run"
# avoid conflict with libbsd - #31259
rm "$pkgdir/usr/share/man/man3/bitstring.3" \
"$pkgdir/usr/share/man/fr/man3/bitstring.3"
rmdir --ignore-fail-on-non-empty "$pkgdir/usr/share/man/man3" \
"$pkgdir/usr/share/man/fr/man3" || true
}
# vim:set ts=2 sw=2 et:
|
