1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# $Id: PKGBUILD 82896 2010-06-18 18:30:20Z ibiru $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
pkgbase=gnash
pkgname=(gnash-common gnash-gtk)
pkgver=0.8.9
pkgrel=9
arch=(i686 x86_64 mips64el)
url="http://www.gnu.org/software/gnash/"
license=(GPL3)
makedepends=(curl giflib libldap sdl agg libjpeg libpng libtool
speex fontconfig libva ffmpeg libxinerama
gstreamer0.10-base gstreamer0.10-ffmpeg
gtk2 libldap xulrunner hicolor-icon-theme desktop-file-utils
pkgconfig boost)
options=(!libtool !emptydirs)
source=(http://ftp.gnu.org/gnu/gnash/${pkgver}/gnash-${pkgver}.tar.bz2
gentoo-ffmpeg-0.8.patch xul8.patch nodebug.patch)
sha256sums=('f90dbdc6f03d787b239b9edacbea077b46d69ae9d85f08af23f256af389c48bd'
'5e6b9c2ccb0f6dda70745712dddf302d2b42895feda850f2ed126bf53d8815ca'
'd484f1c21ef71847a2d4b3dd254d1fa93a58719d45bc9df8b8deabee388ce4e9'
'0ebb104a7632af997c7e6b268755949fa0c1eea5e32015b95a22d63d0e431551')
build() {
cd "$srcdir/gnash-$pkgver"
# Consolidated gentoo patches for ffmpeg compatibility
# as of 2011-10-31
patch -Np1 -i "$srcdir/gentoo-ffmpeg-0.8.patch"
# Patch for compatibility with newer xulrunner headers
patch -Np1 -i "$srcdir/xul8.patch"
# Disable very, very verbose debugging (gigabytes of logs)
patch -Np1 -i "$srcdir/nodebug.patch"
./autogen.sh
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--with-plugins-install=system \
--with-npapi-plugindir=/usr/lib/mozilla/plugins \
--enable-gui=sdl,gtk \
--enable-renderer=agg \
--enable-media=gst,ffmpeg \
--enable-hwaccel=vaapi
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/ if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/ func_append compile_command " -Wl,-O1,--as-needed"\n func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
make
}
package_gnash-common() {
pkgdesc="A GNU Flash movie player"
depends=(curl giflib libldap sdl agg libjpeg libpng libtool
speex fontconfig libva ffmpeg libxinerama
gstreamer0.10-base gstreamer0.10-ffmpeg
boost-libs)
backup=(etc/gnashrc)
cd "$srcdir/gnash-$pkgver"
make DESTDIR="$pkgdir" install
# Split gnash-gtk
mkdir -p "$srcdir"/gtk/{bin,man1,share}
mv "$pkgdir"/usr/bin/{gtk-gnash,gnash-gtk-launcher} "$srcdir/gtk/bin/"
mv "$pkgdir"/usr/share/man/man1/{gtk-gnash,gnash-gtk-launcher}.1 "$srcdir/gtk/man1/"
mv "$pkgdir"/usr/share/{applications,icons} "$srcdir/gtk/share/"
mv "$pkgdir/etc/gnashpluginrc" "$srcdir/gtk/"
}
package_gnash-gtk() {
pkgdesc="A GNU Flash movie player"
depends=("gnash-common=$pkgver"
gtk2 libldap hicolor-icon-theme desktop-file-utils)
install=gnash-gtk.install
backup=(etc/gnashpluginrc)
cd "$srcdir/gnash-$pkgver"
make DESTDIR="$pkgdir" install-plugin
install -d "$pkgdir"/{etc,usr/{bin,share/man/man1}}
mv "$srcdir"/gtk/bin/* "$pkgdir/usr/bin/"
mv "$srcdir"/gtk/man1/* "$pkgdir/usr/share/man/man1/"
mv "$srcdir"/gtk/share/* "$pkgdir/usr/share/"
mv "$srcdir/gtk/gnashpluginrc" "$pkgdir/etc/"
}
|
