blob: 0c0a051ed19a2331299ba00f36b0aa701baadfc8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# $Id: PKGBUILD 90848 2013-05-14 21:40:33Z andrea $
# Maintainer:
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Roman Kyrylych <roman@archlinux.org>
# Contributor: Aurelien Foret <orelien@chez.com>
pkgname=gnokii
pkgver=0.6.31
pkgrel=4
pkgdesc="Tools and user space driver for use with mobile phones"
arch=('i686' 'x86_64')
url="http://www.gnokii.org/"
license=('GPL')
depends=('libusb-compat' 'libxpm' 'bluez' 'libical')
makedepends=('gtk2' 'libmariadbclient' 'postgresql-libs' 'intltool' 'mariadb')
optdepends=('gtk2: xgnokii GUI'
'libmariadbclient: smsd mysql backend'
'postgresql-libs: smsd postgresql backend')
backup=('etc/gnokiirc')
options=('!libtool' '!makeflags')
source=("http://www.gnokii.org/download/$pkgname/$pkgname-${pkgver}.tar.bz2"
'gnokii.patch')
md5sums=('d9627f4a1152d3ea7806df4532850d5f'
'fd1c448114c2e0de8e05981030f0e69f')
build() {
cd ${pkgname}-${pkgver}
# FS#13249
sed -i 's|cellphone|phone|' xgnokii/xgnokii.desktop.in
patch -Np1 -i "${srcdir}/gnokii.patch"
./configure --prefix=/usr \
--sysconfdir=/etc \
--sbindir=/usr/bin \
--enable-security \
--disable-unix98test
make
}
package() {
cd ${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
install -Dm644 Docs/sample/gnokiirc "${pkgdir}/etc/gnokiirc"
}
|
