blob: f2ef8ee2dfee97416e9503986fea126800a533b0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# $Id: PKGBUILD 103047 2013-12-25 19:18:23Z jlichtblau $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Roman Kyrylych <roman@archlinux.org>
# Contributor: Johannes Sjolund <j.sjolund@gmail.com>
pkgname=gnome-commander
pkgver=1.2.8.16
pkgrel=1
pkgdesc='Graphical two-pane filemanager for Gnome'
arch=('i686' 'x86_64' 'mips64el')
url='http://www.nongnu.org/gcmd/'
license=('GPL')
depends=('libgnomeui' 'gnome-vfs' 'gconf' 'python2' 'libsm')
makedepends=('perlxml' 'gnome-doc-utils' 'intltool')
install=$pkgname.install
source=(ftp://ftp.gnome.org/pub/GNOME/sources/gnome-commander/1.2/$pkgname-$pkgver.tar.xz
gnome-commander-1.2.8.15-build.patch)
sha256sums=('84d653fab2eaec233b6d899f339099c2fa2d2d5cbdb7a33bd7022c34ed901347'
'856e9c1a17acbb97772ed93d01d81746098e03f5c06375cc976fc784a0011088')
# mips64el patch
prepare() {
cd "$pkgname-$pkgver"
patch -Np1 -i ${srcdir}/gnome-commander-1.2.8.15-build.patch
}
build() {
cd "$pkgname-$pkgver"
# Python 2 fix
for f in doc/*/gnome-commander.xml; do
sed -i 's:env python:env python2:' "$f"
done
./configure --prefix=/usr --libdir=/usr/lib --sysconfdir=/etc \
--localstatedir=/var --disable-scrollkeeper --enable-python
make
}
package() {
cd "$pkgname-$pkgver"
make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="$pkgdir" install
install -d "$pkgdir/usr/share/gconf/schemas"
gconf-merge-schema "$pkgdir/usr/share/gconf/schemas/$pkgname.schemas" \
--domain "$pkgname" "$pkgdir/etc/gconf/schemas/"*.schemas
rm -rf "$pkgdir/etc/gconf/schemas/"
}
# vim:set ts=2 sw=2 et:
|
