blob: ac257854236759f010fd5e701583d4808b46a73a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# $Id: PKGBUILD 101767 2013-11-30 20:33:20Z bgyorgy $
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=gnome-screensaver
pkgver=3.6.1
pkgrel=7
pkgdesc="Legacy GNOME screensaver"
arch=('i686' 'x86_64')
license=('GPL')
url="https://wiki.gnome.org/Projects/GnomeScreensaver"
backup=(etc/pam.d/gnome-screensaver)
depends=('dbus-glib' 'libgnomekbd' 'gnome-desktop')
makedepends=('intltool' 'gnome-common')
optdepends=('gnome-themes-standard: default background')
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz
gnome-screensaver.pam
move-desktop-file.patch
fix-autoconf.patch
fix-systemd-support.patch
lock_screen_on_suspend.patch
lightdm_switch_user.patch)
sha256sums=('f39b78d4f7fed748c7f0a31d694112fb907c6d3c4e63db22eb858df07e962cd0'
'b6ea9e2eb586d94bcabb617a8f1c2958111df87afdbb51f645882bccdc15cbda'
'4bb96f62aa069c83b629204a79a3f63b146bcaf773569aee8b5dd23fbcd88974'
'c4da9c18b543ecbc781c1f103321b324a855bdd0979fd36b437f6033736ad4bb'
'8aa387578c1756e573f6558a66be25fc96d7e8567fb7bee580159479841f5f45'
'516c479558576c6c5a2509abfcbf4fdafb5953d252e7a4ab972f9db6137daca8'
'5d40bd6e1843150912dc52932eaa94c0f6d57931fd45a3769ef40e2335fe3c6f')
prepare() {
cd "$pkgname-$pkgver"
# Upstream patch that moves gnome-screensaver desktop file out of autostart
patch -Np1 -i "$srcdir/move-desktop-file.patch"
# Fix build
patch -Np1 -i "$srcdir/fix-autoconf.patch"
# Fix systemd support
patch -Np1 -i "$srcdir/fix-systemd-support.patch"
# Lock screen on suspend with systemd
patch -Np1 -i "$srcdir/lock_screen_on_suspend.patch"
# Add support for user switch with LightDM
patch -Np1 -i "$srcdir/lightdm_switch_user.patch"
}
build() {
cd "$pkgname-$pkgver"
autoreconf -fi
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib/$pkgname \
--with-mit-ext
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -Dm644 ../gnome-screensaver.pam "$pkgdir/etc/pam.d/gnome-screensaver"
}
|
