blob: 92166ac5ae6e07e8a763201bf18300414b9dc50e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# $Id: PKGBUILD 88439 2013-04-17 16:49:53Z bgyorgy $
# Contributor: Michael Kanis <mkanis@gmx.de>
pkgname=gsql
pkgver=0.2.2
pkgrel=6
pkgdesc="Integrated database development tool for GNOME"
url="http://gsql.org/"
license=('GPL')
arch=('i686' 'x86_64' 'mips64el')
depends=('gtk2>=2.12' 'gtksourceview2' 'libglade' 'gconf'
'desktop-file-utils' 'libnotify' 'hicolor-icon-theme')
makedepends=('vte' 'libmariadbclient' 'postgresql-libs' 'libssh')
optdepends=('libmariadbclient: MySQL engine'
'libssh: SSH tunneling plugin'
'postgresql-libs: PostgreSQL engine'
'vte: Terminal session plugin')
install=gsql.install
options=(!libtool !emptydirs)
source=(http://gsql.googlecode.com/files/${pkgname}-${pkgver}.tar.bz2)
md5sums=('8f3322a75390584729e84a8570e08bea')
build() {
cd "$srcdir/$pkgname-$pkgver"
sed -i 's/notify_notification_new (subj, message, NULL, NULL);/notify_notification_new (subj, message, NULL);/' libgsql/notify.c
LDFLAGS="$LDFLAGS `pkg-config --libs gthread-2.0`" ./configure --prefix=/usr --sysconfdir=/etc \
--disable-static --without-gnome
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="$pkgdir" install
install -d "${pkgdir}/usr/share/gconf/schemas"
gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" "${pkgdir}"/etc/gconf/schemas/*.schemas
rm -f "${pkgdir}"/etc/gconf/schemas/*.schemas
}
|
