blob: fc7a8dd0ee6e4b0f19cd38c98150665a98a9e463 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Daniel Micay <danielmicay@gmail.com>
# Contributor: Arch Haskell Team <arch-haskell@haskell.org>
# Contributor: Lex Black <autumn-wind at web dot de>
_hkgname=highlighting-kate
pkgname=haskell-highlighting-kate
pkgver=0.5.3.8
pkgrel=1
pkgdesc="Syntax highlighting"
url="http://hackage.haskell.org/package/$_hkgname"
license=('GPL')
arch=('i686' 'x86_64')
makedepends=('ghc')
depends=('haskell-blaze-html>=0.4.2' 'haskell-containers' 'haskell-filepath' 'haskell-mtl' 'haskell-parsec' 'haskell-pcre-light')
source=(http://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
install=$pkgname.install
md5sums=('c3fdfadddfdf198af6192b9bf437a422')
build() {
cd "$srcdir/$_hkgname-$pkgver"
runhaskell Setup configure -O --enable-split-objs --enable-shared \
--prefix=/usr --docdir=/usr/share/doc/$pkgname --libsubdir=\$compiler/site-local/\$pkgid
runhaskell Setup build
runhaskell Setup haddock
runhaskell Setup register --gen-script
runhaskell Setup unregister --gen-script
sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}
package() {
cd "$srcdir/$_hkgname-$pkgver"
install -Dm744 register.sh "$pkgdir/usr/share/haskell/$pkgname/register.sh"
install -m744 unregister.sh "$pkgdir/usr/share/haskell/$pkgname/unregister.sh"
install -dm755 "$pkgdir/usr/share/doc/ghc/html/libraries"
ln -s /usr/share/doc/$pkgname/html "$pkgdir/usr/share/doc/ghc/html/libraries/$_hkgname"
runhaskell Setup copy --destdir="$pkgdir"
}
|
