blob: db574668ed2df39ea97d926704ece8f019f19486 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id: PKGBUILD 75909 2012-09-05 10:20:43Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Arch Haskell Team <arch-haskell@haskell.org>
pkgname=haskell-hslogger
pkgver=1.2.0
pkgrel=1
pkgdesc="Versatile logging framework"
url="http://hackage.haskell.org/package/hslogger"
license=('LGPL')
arch=('i686' 'x86_64')
depends=('ghc=7.4.2-1' 'haskell-mtl=2.1.1-1' 'haskell-network=2.3.0.14-1')
install=${pkgname}.install
source=(http://hackage.haskell.org/packages/archive/hslogger/${pkgver}/hslogger-${pkgver}.tar.gz)
md5sums=('e0737887b0df75a3781989c8f6689850')
build() {
cd ${srcdir}/hslogger-${pkgver}
runhaskell Setup configure -p --prefix=/usr --docdir=/usr/share/doc/${pkgname} -O \
--enable-split-objs --enable-shared --libsubdir=\$compiler/site-local/\$pkgid \
--enable-library-profiling
runhaskell Setup build
runhaskell Setup haddock
runhaskell Setup register --gen-script
runhaskell Setup unregister --gen-script
sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}
package() {
cd ${srcdir}/hslogger-${pkgver}
install -D -m744 register.sh ${pkgdir}/usr/share/haskell/${pkgname}/register.sh
install -m744 unregister.sh ${pkgdir}/usr/share/haskell/${pkgname}/unregister.sh
install -d -m755 ${pkgdir}/usr/share/doc/ghc/html/libraries
ln -s /usr/share/doc/${pkgname}/html ${pkgdir}/usr/share/doc/ghc/html/libraries/hslogger
runhaskell Setup copy --destdir=${pkgdir}
}
|
