blob: def9c2c714ecb7be88b47b0aff7a504ab90ddb9d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# $Id: PKGBUILD 58948 2011-11-20 18:06:21Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
pkgname=haskell-pango
pkgver=0.12.2
pkgrel=1
pkgdesc="Binding to the pango library for Gtk2Hs."
url="http://hackage.haskell.org/package/pango"
license=('LGPL2.1')
arch=('i686' 'x86_64')
depends=('ghc' 'pango' 'haskell-glib' 'haskell-cairo')
makedepends=("gtk2hs-buildtools")
provides=('gtk2hs-pango')
replaces=('gtk2hs-pango')
conflicts=('gtk2hs-pango')
options=('strip')
source=(http://hackage.haskell.org/packages/archive/pango/${pkgver}/pango-${pkgver}.tar.gz)
install=gtk2hs-pango.install
md5sums=('301efd2d2348698ce8d586ee14c36e2b')
build() {
cd ${srcdir}/pango-${pkgver}
runhaskell Setup configure -O -p --enable-split-objs --enable-shared \
--prefix=/usr --docdir=/usr/share/doc/haskell-pango \
--libsubdir=\$compiler/site-local/\$pkgid
runhaskell Setup build
runhaskell Setup haddock
runhaskell Setup register --gen-script
runhaskell Setup unregister --gen-script
sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}
package() {
_ghcver=`pacman -Q ghc | cut -f2 -d\ | cut -f1 -d-`
depends=("ghc=${_ghcver}" 'pango' 'haskell-glib' 'haskell-cairo')
cd ${srcdir}/pango-${pkgver}
install -D -m744 register.sh ${pkgdir}/usr/share/haskell/gtk2hs-pango/register.sh
install -m744 unregister.sh ${pkgdir}/usr/share/haskell/gtk2hs-pango/unregister.sh
install -d -m755 ${pkgdir}/usr/share/doc/ghc/html/libraries
ln -s /usr/share/doc/haskell-pango/html ${pkgdir}/usr/share/doc/ghc/html/libraries/pango
runhaskell Setup copy --destdir=${pkgdir}
}
|
