blob: a67916ef41a45f08bbbf726a5842aa4c81ee2c68 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# $Id: PKGBUILD 94887 2013-08-01 06:55:02Z bpiotrowski $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
pkgname=hedgewars
pkgver=0.9.19
pkgrel=2
pkgdesc="Free Worms-like turn based strategy game"
arch=('i686' 'x86_64' 'mips64el')
url="http://hedgewars.org"
license=('GPL' 'custom')
depends=('qt4' 'sdl' 'sdl_mixer' 'sdl_image' 'sdl_net' 'sdl_ttf' 'lua51' 'ffmpeg' 'glut')
makedepends=('fpc' 'cmake'
# haskell specific
'ghc'
'haskell-network'
'haskell-bytestring-show'
'haskell-utf8-string'
'haskell-dataenc'
'haskell-hslogger'
'haskell-vector'
'haskell-random')
source=(http://download.gna.org/hedgewars/hedgewars-src-$pkgver.tar.bz2
hedgewars.desktop
hedgewars.png
build-fix.patch
ffmpeg2.0.patch)
md5sums=('51d84ad6ea00e9894e6119b118b4a523'
'48c66a3204d4fa0a69e9aa46f7c31e0c'
'eeb14d50df39063549ac5eca9dbc65d1'
'a9d7b0ba72cbeb7fc74fce459db9dd90'
'da84d64a252579236d3ff0cc6e008e72')
prepare() {
cd $pkgname-src-$pkgver
patch -Rp1 <$srcdir/build-fix.patch
patch -Np1 -i ../ffmpeg2.0.patch
}
build() {
cd $pkgname-src-$pkgver
cmake \
-DCMAKE_BUILD_TYPE="Release" \
-DCMAKE_INSTALL_PREFIX=/usr \
-DDATA_INSTALL_DIR=/usr/share/hedgewars \
-DWITH_SERVER=1 \
-DSYSTEM_PHYSFS=OFF .
make
}
package() {
cd $pkgname-src-$pkgver
make DESTDIR=$pkgdir install
install -D -m644 Fonts_LICENSE.txt $pkgdir/usr/share/licenses/$pkgname/Fonts_LICENSE.txt
install -D -m644 $srcdir/hedgewars.png $pkgdir/usr/share/pixmaps/hedgewars.png
install -D -m644 $srcdir/hedgewars.desktop $pkgdir/usr/share/applications/hedgewars.desktop
}
|
