blob: a24c7873200051709aa5527e8a4d70896aa47e97 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# $Id: PKGBUILD 91949 2013-05-30 09:42:30Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Roberto Alsina <ralsina@kde.org>
# Contributor: scj <scj(at)archlinux(dot)us>
pkgname=incron
pkgver=0.5.10
pkgrel=6
pkgdesc="Like the regular cron but is driven by filesystem events instead of time periods"
arch=('i686' 'x86_64' 'mips64el')
url="http://incron.aiken.cz/"
license=('GPL')
depends=('gcc-libs' 'bash')
install=incron.install
options=('emptydirs')
source=("http://inotify.aiken.cz/download/incron/$pkgname-$pkgver.tar.gz"
'incrond.service')
md5sums=('67f8b671db8169edccc8ef11c7d2c8be'
'4be206ba6ecacd9d2006cdc72b4604db')
prepare() {
cd "${srcdir}"/$pkgname-$pkgver
sed -i '1,1i#include <unistd.h>' inotify-cxx.cpp icd-main.cpp
sed -i '1,1i#include <stdio.h>' icd-main.cpp inotify-cxx.cpp usertable.cpp appargs.cpp
sed -i 's|strchr(s,|(char*)strchr(s,|' incroncfg.cpp
sed -i 's|$(DESTDIR)$(PREFIX)/sbin/|$(DESTDIR)$(PREFIX)/bin/|g' Makefile
}
build() {
cd "${srcdir}"/$pkgname-$pkgver
make
}
package() {
cd "${srcdir}"/$pkgname-$pkgver
install -d "${pkgdir}"/usr/share/man "${pkgdir}"/usr/{s,}bin
make PREFIX="${pkgdir}"/usr \
MANPATH="${pkgdir}"/usr/share/man \
USERDATADIR="${pkgdir}"/var/spool/incron \
CFGDIR="${pkgdir}"/etc \
SYSDATADIR="${pkgdir}"/etc/incron.d install
install -Dm0644 "${srcdir}/incrond.service" "${pkgdir}/usr/lib/systemd/system/incrond.service"
rmdir $pkgdir/usr/sbin
}
|
