blob: ab1e13a7fe502a45edae7ebcd44e88d757469a63 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# $Id: PKGBUILD 75723 2012-08-29 14:02:05Z seblu $
# Maintainer: Sébastien Luttringer <seblu@aur.archlinux.org>
# Contributor: Andrea Zucchelli <zukka77@gmail.com>
pkgname=keepalived
pkgver=1.2.7
pkgrel=1
pkgdesc='Failover and monitoring daemon for LVS clusters'
arch=('i686' 'x86_64')
url='http://www.keepalived.org/'
license=('GPL2')
backup=('etc/keepalived/keepalived.conf' 'etc/conf.d/keepalived')
depends=('openssl' 'popt' 'libnl1')
source=("http://www.keepalived.org/software/$pkgname-$pkgver.tar.gz"
'keepalived.rc'
'keepalived.service'
'keepalived.conf')
md5sums=('8551a34ee048895dbe5350a031ff29c1'
'0d7ea6296bce403a5d24be305a0a9d73'
'dd0a003a24057eba1e4dc09f372aaa52'
'9c8142da8730ad27a345587dea83ced7')
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr --sysconfdir=/etc
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
# clean pacakge init scripts
rm -r "$pkgdir/etc/rc.d/init.d" "$pkgdir/etc/sysconfig"
# move examples to /usr/share
install -d -m 755 "$pkgdir/usr/share/$pkgname"
mv "$pkgdir/etc/keepalived/samples" "$pkgdir/usr/share/$pkgname/samples"
# add initscripts
cd ..
install -D -m 755 $pkgname.rc "$pkgdir/etc/rc.d/$pkgname"
install -D -m 644 $pkgname.conf "$pkgdir/etc/conf.d/$pkgname"
install -D -m 644 $pkgname.service \
"$pkgdir/usr/lib/systemd/system/$pkgname.service"
}
# vim:set ts=2 sw=2 ft=sh et:
|
