blob: b38459ad6e0b57a47ba2dcb757ef91225070a85b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 83016 2013-01-26 15:16:16Z bgyorgy $
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
pkgbase=libaccounts-qt
_pkgbase=accounts-qt
pkgname=('libaccounts-qt' 'libaccounts-qt-doc')
pkgver=1.4
pkgrel=1
pkgdesc="Qt-based client library for accessing the online accounts database"
arch=('i686' 'x86_64')
url="http://code.google.com/p/accounts-sso/"
license=('LGPL')
depends=('qt' 'libaccounts-glib')
makedepends=('doxygen' 'graphviz' 'ttf-dejavu')
options=('!emptydirs')
source=(http://accounts-sso.googlecode.com/files/$_pkgbase-$pkgver.tar.bz2)
sha1sums=('135fdaa766da070b2ad41ff4c33c663f4d321c8e')
build() {
cd "$srcdir/$_pkgbase-$pkgver"
# Do not install tests
echo 'INSTALLS =' >>tests/accountstest.pro
qmake PREFIX=/usr LIBDIR=/usr/lib
make
}
package_libaccounts-qt() {
cd "$srcdir/$_pkgbase-$pkgver"
make INSTALL_ROOT="$pkgdir" install
# Split out documentation
mv "$pkgdir/usr/share/doc" "$srcdir"
}
package_libaccounts-qt-doc() {
pkgdesc="Developer documention of signon"
depends=()
mkdir -p "$pkgdir/usr/share"
mv "$srcdir/doc" "$pkgdir/usr/share"
}
|
