blob: ca900239ee7a9f7beca022373decca6c235c6c54 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 99160 2013-10-25 08:29:02Z alucryd $
# Maintainer: Maxime Gauduin <alucryd at gmail dot com>
# Contributor: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Branchini Massimo <max dot bra dot gtalk at gmail dot com
pkgbase=libdbusmenu
pkgname=('libdbusmenu-glib' 'libdbusmenu-gtk3')
pkgver=12.10.2
pkgrel=3
pkgdesc="A library for passing menus over DBus"
arch=('i686' 'x86_64')
url="https://launchpad.net/libdbusmenu"
license=('GPL3')
makedepends=('gnome-doc-utils' 'gobject-introspection' 'gtk3' 'intltool' 'vala')
options=('!emptydirs')
source=("http://launchpad.net/dbusmenu/${pkgver%.?}/${pkgver}/+download/${pkgbase}-${pkgver}.tar.gz")
sha256sums=('9d6ad4a0b918b342ad2ee9230cce8a095eb601cb0cee6ddc1122d0481f9d04c9')
build() {
cd ${pkgbase}-${pkgver}
export HAVE_VALGRIND_TRUE='#'
export HAVE_VALGRIND_FALSE=''
./configure --prefix='/usr' --sysconfdir='/etc' --localstatedir='/var' --disable-{dumper,static,tests}
make
}
package_libdbusmenu-glib() {
depends=('glib2')
cd ${pkgbase}-${pkgver}
make -C libdbusmenu-glib DESTDIR="${pkgdir}" install
}
package_libdbusmenu-gtk3() {
depends=('gtk3' 'libdbusmenu-glib')
cd ${pkgbase}-${pkgver}
make -C libdbusmenu-glib DESTDIR="${pkgdir}" install
make -C libdbusmenu-gtk DESTDIR="${pkgdir}" install
make -C libdbusmenu-glib DESTDIR="${pkgdir}" uninstall
}
# vim: ts=2 sw=2 et:
|
