blob: e33eaf34fabb519923dad17896ce85231e9e6dfd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 102256 2013-12-07 10:36:40Z bpiotrowski $
# Maintainer: Kyle Keen <keenerd@gmail.com>
# Contributor: Dominik Heidler <dheidler@gmail.com>
pkgname=libuhd
pkgver=3.5.4
_verstring=003_005_004
pkgrel=4
pkgdesc="Universal Software Radio Peripheral (USRP) userspace driver"
arch=('x86_64' 'i686')
url="http://code.ettus.com/redmine/ettus/projects/uhd/wiki"
license=('GPL')
depends=('boost-libs' 'orc' 'libusbx')
makedepends=('cmake' 'boost' 'python2-cheetah')
source=("libuhd-$pkgver.tar.gz::https://codeload.github.com/EttusResearch/uhd/tar.gz/release_$_verstring")
md5sums=('e90c95483a52b75cacc85f4fb0ef63ed')
build() {
cd "$srcdir/uhd-release_$_verstring/host"
# fix for py2
find -name "*.py" | xargs sed -i "s|#!/usr/bin/env python$|#!/usr/bin/env python2|"
mkdir -p build
cd build
cmake .. -DCMAKE_INSTALL_PREFIX=/usr/ \
-DPYTHON_EXECUTABLE=/usr/bin/python2 \
-DENABLE_EXAMPLES=OFF \
-DENABLE_UTILS=ON \
-DENABLE_TESTS=OFF \
-DENABLE_E100=ON
# e100 is disabled by default for now, check that on future releases
make
}
check() {
cd "$srcdir/uhd-release_$_verstring/host/build"
make test
}
package() {
cd "$srcdir/uhd-release_$_verstring/host/build"
make DESTDIR="$pkgdir" install
install -Dm644 "$pkgdir/usr/share/uhd/utils/uhd-usrp.rules" "$pkgdir/usr/lib/udev/rules.d/10-uhd-usrp.rules"
}
|
