blob: fdb19d7a2f754732000fbf8569d0b5684321db13 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# $Id: PKGBUILD 69420 2012-04-16 09:40:09Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: hydro <hydro@freenet.de>
pkgname=libzen
pkgver=0.4.26
pkgrel=1
pkgdesc="shared library for libmediainfo and mediainfo"
arch=('i686' 'x86_64')
url="http://mediainfo.sourceforge.net"
license=('BSD')
depends=('gcc-libs')
makedepends=('libtool' 'automake' 'autoconf')
options=('!libtool')
source=(http://downloads.sourceforge.net/zenlib/${pkgname}_${pkgver}.tar.bz2)
md5sums=('6509bd3787509f4e62e48a99884db636')
build() {
cd $srcdir/ZenLib/Project/GNU/Library
[ -x configure ] || sh ./autogen
[ -f Makefile ] || ./configure --prefix=/usr --enable-shared
make clean
make
}
package() {
cd $srcdir/ZenLib/Project/GNU/Library
make DESTDIR=$pkgdir install
install -dm 755 $pkgdir/usr/include/ZenLib
install -m 644 $srcdir/ZenLib/Source/ZenLib/*.h $pkgdir/usr/include/ZenLib
for i in HTTP_Client Format/Html Format/Http; do
install -dm0755 $pkgdir/usr/include/ZenLib/$i
install -m0644 $srcdir/ZenLib/Source/ZenLib/$i/*.h $pkgdir/usr/include/ZenLib/$i
done
install -dm 755 $pkgdir/usr/lib/pkgconfig
install -m 644 $srcdir/ZenLib/Project/GNU/Library/libzen.pc $pkgdir/usr/lib/pkgconfig
sed -i -e 's|Version: |Version: '$pkgver'|g' $pkgdir/usr/lib/pkgconfig/libzen.pc
install -D -m 644 $srcdir/ZenLib/License.txt $pkgdir/usr/share/licenses/libzen/License.txt
}
|
