blob: 8290c365965367eaf7e2c22f76ad2d0328e3cb32 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# $Id: PKGBUILD 92554 2013-06-08 11:18:50Z bpiotrowski $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Geoffroy Carrier <geoffroy@archlinux.org>
# Contributor: William Rea <sillywilly@gmail.com>
# Contributor: Robert Emil Berge <filoktetes@linuxophic.org>
pkgname=lilypond
pkgver=2.16.2
pkgrel=3
pkgdesc="An automated music engraving system"
arch=('i686' 'x86_64' 'mips64el')
url="http://lilypond.org"
license=('GPL')
depends=('guile1.8' 'python2' 'texlive-core' 'ghostscript' 'pango' 'fontconfig')
makedepends=('flex' 'bison' 'gettext' 'mftrace' 'texinfo' 'fontforge' 't1utils'
'gsfonts' 'texi2html')
options=('emptydirs')
install=lilypond.install
source=(http://download.linuxaudio.org/lilypond/sources/v2.16/$pkgname-$pkgver.tar.gz)
md5sums=('6db27f17d47e4f66a3b0716c65db3041')
prepare() {
cd "$srcdir/$pkgname-$pkgver"
# python2 fix
for file in $(find . -name '*.py' -print); do
sed -i 's_^#!.*/usr/bin/python_#!/usr/bin/python2_' $file
sed -i 's_^#!.*/usr/bin/env.*python_#!/usr/bin/env python2_' $file
done
sed -i 's|GUILE_CFLAGS=.*|GUILE_CFLAGS="`pkg-config --cflags guile-1.8`"|' configure
sed -i 's|GUILE_LDFLAGS=.*|GUILE_LDFLAGS="`pkg-config --libs guile-1.8`"|' configure
rm -rf python/out/
}
build() {
cd "$srcdir/$pkgname-$pkgver"
export PYTHON=/usr/bin/python2
export GUILE=/usr/bin/guile1.8
export GUILE_CONFIG=/usr/bin/guile-config1.8
./configure --prefix=/usr --disable-documentation
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" vimdir="/usr/share/vim/vimfiles" install
}
|
