blob: 4a24f7182c5879d9e20ddd99bd684889a71432fd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id: PKGBUILD 104487 2014-01-21 17:50:07Z bpiotrowski $
# Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: J. W. Birdsong <jwbirdsong AT gmail DOT com>
pkgname=luakit
pkgver=2012.09.13.r1
_pkgver=2012.09.13-r1
pkgrel=6
pkgdesc='Fast, small, Webkit based browser framework extensible by Lua'
arch=('i686' 'x86_64')
url='http://mason-larobina.github.com/luakit/'
license=('GPL3')
depends=('webkitgtk2' 'lua51-filesystem' 'libunique' 'desktop-file-utils' 'luajit')
makedepends=('help2man')
options=(!makeflags)
install='luakit.install'
source=($pkgname-$pkgver.tar.gz::https://github.com/mason-larobina/luakit/tarball/$_pkgver)
md5sums=('77b02e6d19ba021409f1778fddd94a42')
prepare() {
cd mason-larobina-luakit-*
sed -i '1s,lua,luajit,' build-utils/gentokens.lua
}
build() {
cd mason-larobina-luakit-*
make USE_LUAJIT=1 PREFIX=/usr all
}
package() {
cd mason-larobina-luakit-*
make PREFIX=/usr DESTDIR="$pkgdir" install
chmod -x "$pkgdir"/usr/share/pixmaps/luakit.png # FS#32938
}
|