blob: bb1990f2a126b05fc82a66506f2670442354b570 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# $Id: PKGBUILD 93034 2013-06-22 17:02:30Z seblu $
# Maintainer: Sébastien Luttringer
# Contributor: SpepS <dreamspepser at yahoo dot it>
# Contributor: Laszlo Papp <djszapi at archlinux us>
# Contributor: Donald Ephraim Curtis <dcurtis@gmail.com>
pkgbase=luaposix
pkgname=('lua-posix' 'lua51-posix')
pkgver=5.1.28
pkgrel=1
pkgdesc='A POSIX library for Lua programming language'
arch=('i686' 'x86_64' 'mips64el')
url='https://github.com/luaposix/luaposix'
license=('GPL' 'LGPL')
makedepends=('lua' 'lua51' 'lua51-bitop' 'git')
options=('!libtool')
source=("$pkgname-$pkgver.tar.gz::https://github.com/luaposix/luaposix/archive/v$pkgver.tar.gz")
md5sums=('0ea20ea21bd9f92b79041beb6d41393e')
prepare() {
# do bootstrap in prepare, as it clone external git
(cd $pkgbase-$pkgver && ./bootstrap)
cp -r $pkgbase-$pkgver $pkgbase-$pkgver-51
}
build() {
msg2 'Build with lua 5.2'
cd $pkgbase-$pkgver
./configure \
LUA=/usr/bin/lua \
--prefix=/usr \
--libdir=/usr/lib/lua/5.2 \
--datadir=/usr/share/lua/5.2 \
--docdir=/usr/share/doc/lua-posix
make
msg2 'Build with lua 5.1'
cd "$srcdir/$pkgbase-$pkgver-51"
./configure \
LUA=/usr/bin/lua5.1 \
LUA_INCLUDE=-I/usr/include/lua5.1 \
--prefix=/usr \
--libdir=/usr/lib/lua/5.1 \
--datadir=/usr/share/lua/5.1 \
--docdir=/usr/share/doc/lua51-posix
make
}
package_lua-posix() {
depends=('lua')
cd $pkgbase-$pkgver
make DESTDIR="$pkgdir/" install
}
package_lua51-posix() {
depends=('lua51' 'lua51-bitop')
conflicts=('luaposix')
replaces=('luaposix')
cd $pkgbase-$pkgver-51
make DESTDIR="$pkgdir/" install
}
# vim:set ts=2 sw=2 et:
|
