blob: 5a1121a2bd7bcb968f1818003e649f9676a8dc32 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id: PKGBUILD 68146 2012-03-18 18:24:42Z cbrannon $
# Maintainer: Chris Brannon <cmbrannon79@gmail.com>
# Contributor: Geoffroy Carrier <geoffroy@archlinux.org>
pkgname=luarocks
pkgver=2.0.8
pkgrel=1
pkgdesc='Deployment and management system for Lua modules'
arch=('i686' 'x86_64' 'mips64el')
url="http://luarocks.org/"
depends=('lua' 'unzip' 'zip' 'curl')
optdepends=('cvs: for fetching sources from CVS repositories'
'git: for fetching sources from git repositories'
'mercurial: for fetching sources from mercurial repositories'
'luasec: HTTPS support'
'cmake: for building rocks that use the cmake build system')
license=('custom')
options=('!makeflags')
source=(http://luarocks.org/releases/$pkgname-$pkgver.tar.gz)
build() {
cd "$srcdir/$pkgname-$pkgver"
# I added --with-downloader=curl, because luarocks already uses curl
# for uploading. May as well use curl for downloading.
./configure --prefix=/usr --sysconfdir=/etc/luarocks --with-downloader=curl
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make install DESTDIR="$pkgdir"
install -D COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
md5sums=('07cf84e352d86fe161f7b2ec43f360cc')
|
