blob: d5a9410d2047573f43050b310ebfdd3b079c437b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 105669 2014-02-13 11:02:33Z spupykin $
# Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Rafael Ferreira <josephgbr@archlinux.info>
pkgname=lucene++
pkgver=3.0.5
pkgrel=2
pkgdesc='C++ port of the popular Java Lucene library'
arch=(i686 x86_64)
url='https://github.com/luceneplusplus/LucenePlusPlus'
license=('GPL' 'Apache')
depends=('boost-libs')
makedepends=('boost' 'cmake')
source=(https://github.com/luceneplusplus/LucenePlusPlus/archive/rel_$pkgver.tar.gz)
md5sums=('da785510716a759d7d37a2ee52cb8140')
prepare() {
mkdir build
sed -i \
-e 's#SET(LUCENE++_VERSION_REVISION.*#SET(LUCENE++_VERSION_REVISION "5")#' \
-e 's#SET(LUCENE++_VERSION_PATCH.*#SET(LUCENE++_VERSION_PATCH "0")#' \
$srcdir/LucenePlusPlus-rel_$pkgver/CMakeLists.txt
}
build() {
cd build
cmake ../LucenePlusPlus-rel_$pkgver \
-DCMAKE_INSTALL_PREFIX=/usr \
-DLIB_DESTINATION=/usr/lib \
-DBoost_LIBRARY_DIR=/usr/lib \
-DENABLE_CUSTOM_ALLOCATOR='FALSE'
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|
