blob: c4a48682bdd82f0f073b5c1aa3d8c2652a8ea607 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# $Id: PKGBUILD 74796 2012-08-05 13:47:21Z stativ $
# Maintainer: Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Initial contributor: flixie <69one@gmx.net>
# Contributor: Imanol Celaya <ornitorrincos@archlinux-es.org>
pkgname=luxrender
pkgver=1.0rc3
_pkgver=9ed6b94cef05
pkgrel=1
pkgdesc="Rendering system for physically correct, unbiased image synthesis"
arch=('i686' 'x86_64')
url="http://www.luxrender.net/"
license=('GPL')
depends=('boost-libs' 'freeimage' 'openexr' 'libcl')
optdepends=('luxblend25: Blender exporter' 'qt: Qt GUI' \
'python: Python interface (pylux)'
'nvidia-utils: OpenCL support for nVidia GPUs' \
'amdstream: OpenCL support for AMD GPUs' \
'intel-opencl-sdk: OpenCL support for Intel CPUs')
makedepends=('cmake' 'boost' 'qt' "luxrays=$pkgver" 'python' 'opencl-headers')
source=(https://bitbucket.org/luxrender/lux/get/$_pkgver.tar.bz2 \
boost_1.50_fix.diff)
md5sums=('54ff625a7833541c3cff5f0a77a93863'
'4cddc606ef3ea7f0bbbc9b3415be38b0')
build() {
cd "$srcdir"/luxrender-lux-$_pkgver
# fix for boost 1.50
# the boost::TIME_UTC has been renamed due to the conflict with C++11
patch -Np1 < "$srcdir"/boost_1.50_fix.diff || true
export CXXFLAGS="$CXXFLAGS -lpthread"
cmake -DCMAKE_INSTALL_PREFIX=/usr \
-DLUXRAYS_DISABLE_OPENCL=OFF \
-DPYTHON_CUSTOM=ON \
-DPYTHON_LIBRARIES=/usr/lib/libpython3.2mu.so \
-DPYTHON_INCLUDE_PATH=/usr/include/python3.2mu/ \
.
make
}
package() {
cd "$srcdir"/luxrender-lux-$_pkgver
make DESTDIR="$pkgdir" install
# fix library path on x86_64
[ "$CARCH" = "x86_64" ] && mv "$pkgdir"/usr/lib64 "$pkgdir"/usr/lib
#install pylux
install -D -m644 pylux.so "$pkgdir"/usr/lib/python3.2/pylux.so
}
# vim:set ts=2 sw=2 et:
|
