blob: c720ff4c4e6bc1b60848d970b01128684804ab77 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 102259 2013-12-07 10:36:44Z bpiotrowski $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: David Dent <thewinch@gmail.com>
# Contributor: orbisvicis <orbisvicis@gmail.com>
pkgname=mapnik
pkgver=2.2.0
pkgrel=5
pkgdesc="Free Toolkit for developing mapping applications. Above all Mapnik is about rendering beautiful maps"
arch=('i686' 'x86_64' 'mips64el')
url="http://mapnik.org/"
license=('LGPL')
depends=('boost-libs' 'icu' 'libpng' 'libjpeg' 'libtiff' 'freetype2'
'libxml2' 'python2' 'proj' 'cairo' 'cairomm' 'pycairo'
'postgresql-libs' 'postgis' 'gdal' 'curl' 'libltdl')
optdepends=('libxslt: Web Map Service'
'python2-lxml: Web Map Service'
'python2-pillow: Web Map Service'
'python-nose: Web Map Service'
'apache: Web Map Service'
'mod_fastcgi: Web Map Service - or:'
'mod_fcgid: Web Map Service - or:'
'mod_wsgi2: Web Map Service')
makedepends=('scons' 'boost')
install="mapnik.install"
source=("https://github.com/mapnik/mapnik/archive/v$pkgver.tar.gz")
md5sums=('b837931c7f1a4dc630d8550d3e635036')
build() {
cd "$srcdir/$pkgname-$pkgver"
sed -i 's|lib64|lib|g' SConstruct
sed -i 's|python|python2|' \
utils/performance/mapnik-speed-check \
utils/upgrade_map_xml/*.py
scons configure \
PREFIX="/usr" \
INPUT_PLUGINS=all \
DESTDIR="$pkgdir"
scons $MAKEFLAGS
}
package(){
cd "$srcdir/$pkgname-$pkgver"
scons install
}
|
