blob: eb7b68c6d392db4b1e215daff5df4875b909bbcf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# $Id: PKGBUILD 76011 2012-09-08 21:04:59Z ttopper $
# Contributor: G_Syme <demichan(at)mail(dot)upb(dot)de>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
# Maintainer: Thorsten Töpper <atsutane-tu@freethoughts.de>
pkgname=mathomatic
pkgver=16.0.3
pkgrel=1
pkgdesc="General purpose Computer Algebra System written in C"
arch=('i686' 'x86_64')
license=('LGPL')
url="http://mathomatic.orgserve.de/math/"
depends=('readline')
makedepends=('time')
optdepends=('python2: for running /usr/share/doc/mathomatic/factorial/factorial'
'bash: for running a test script'
'm4: for complex operations using the matho script'
'rlwrap: for readline editing'
'gnuplot: for plotting')
source=(http://mathomatic.org/$pkgname-$pkgver.tar.bz2)
md5sums=('0bd4b73e364d05b7a5b855f19c91b6bd')
build() {
cd "$srcdir"/$pkgname-$pkgver
# python2 fix
for file in primes/{primorial,matho-sum,matho-mult} examples/factorial; do
sed -i 's_#!.*/usr/bin/python_#!/usr/bin/python2_' $file
sed -i 's_#!.*/usr/bin/env.*python_#!/usr/bin/env python2_' $file
done
make READLINE=1
make test
cd "$srcdir"/$pkgname-$pkgver/primes
make
make test
}
package() {
cd "$srcdir"/$pkgname-$pkgver
make prefix="$pkgdir"/usr m4install
sed -i 's+/build/pkg++' "$pkgdir"/usr/bin/matho
cd "$srcdir"/$pkgname-$pkgver/primes
make prefix="$pkgdir"/usr install
}
# vim:set ts=2 sw=2 et:
|
