blob: cbcc78c6f1c6bc8cf3ea7e0369dc859fec0055b7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
|
# $Id: PKGBUILD 102726 2013-12-17 20:17:14Z bgyorgy $
# Maintainer: Jonathan Conder <jonno.conder@gmail.com>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
pkgbase=mythplugins
pkgname=('mythplugins-mytharchive'
'mythplugins-mythbrowser'
'mythplugins-mythgallery'
'mythplugins-mythgame'
'mythplugins-mythmusic'
'mythplugins-mythnetvision'
'mythplugins-mythnews'
'mythplugins-mythweather'
'mythplugins-mythweb'
'mythplugins-mythzoneminder')
pkgver=0.27
pkgrel=4
epoch=1
arch=('i686' 'x86_64')
url="http://www.mythtv.org"
license=('GPL')
makedepends=('cdrkit' 'dvdauthor' 'dvd+rw-tools' 'ffmpeg' 'flac' 'libexif'
'libvorbis' 'mesa' 'mesa-libgl' 'mplayer' 'mythtv'
'perl-datetime-format-iso8601' 'perl-date-manip' 'perl-image-size'
'perl-json' 'perl-libwww' 'perl-soap-lite' 'perl-xml-sax'
'perl-xml-simple' 'perl-xml-xpath' 'python2-oauth' 'python2-pillow'
'python2-pycurl' 'zlib')
source=("mythtv-$pkgver.tar.gz::https://github.com/MythTV/mythtv/archive/v$pkgver.tar.gz"
"mythweb-$pkgver.tar.gz::https://github.com/MythTV/mythweb/archive/v$pkgver.tar.gz"
'cdparanoia.patch')
sha256sums=('494ebd7ee384e751c05ee0a1b3dcd3618caf72f1e94810381c09c2b5d1c799f0'
'7e54d6b388e2e8f3e50515c3fe46113f4217e3989242459a0fa73c928dcca494'
'004f1e4734830709d2ab5ebb804560514f2bf525abc2f11142501a81eba0754c')
prepare() {
cd "$srcdir/mythtv-$pkgver/$pkgbase"
find . -name '*.py' -type f | xargs sed -i 's@^#!.*python$@#!/usr/bin/python2@'
patch -Np1 -i "$srcdir/cdparanoia.patch"
cd "$srcdir/mythweb-$pkgver"
sed -re 's@/usr/local.*/usr/share@/usr/share@' -i 'mythweb.php'
}
build() {
cd "$srcdir/mythtv-$pkgver/$pkgbase"
./configure --prefix=/usr \
--enable-all \
--python=python2
qmake-qt4 mythplugins.pro
make -s
}
package_mythplugins-mytharchive() {
pkgdesc="Create DVDs or archive recorded shows in MythTV"
depends=('cdrkit' 'dvdauthor' 'dvd+rw-tools' 'ffmpeg' 'mythtv'
'python2-pillow')
cd "$srcdir/mythtv-$pkgver/$pkgbase/mytharchive"
make INSTALL_ROOT="$pkgdir" install
}
package_mythplugins-mythbrowser() {
pkgdesc="Mini web browser for MythTV"
depends=('mythtv')
cd "$srcdir/mythtv-$pkgver/$pkgbase/mythbrowser"
make INSTALL_ROOT="$pkgdir" install
}
package_mythplugins-mythgallery() {
pkgdesc="Image gallery plugin for MythTV"
depends=('libexif' 'mythtv')
cd "$srcdir/mythtv-$pkgver/$pkgbase/mythgallery"
make INSTALL_ROOT="$pkgdir" install
}
package_mythplugins-mythgame() {
pkgdesc="Game emulator plugin for MythTV"
depends=('mythtv')
cd "$srcdir/mythtv-$pkgver/$pkgbase/mythgame"
make INSTALL_ROOT="$pkgdir" install
}
package_mythplugins-mythmusic() {
pkgdesc="Music playing plugin for MythTV"
depends=('mythtv' 'libcdio-paranoia')
cd "$srcdir/mythtv-$pkgver/$pkgbase/mythmusic"
make INSTALL_ROOT="$pkgdir" install
}
package_mythplugins-mythnetvision() {
pkgdesc="MythNetvision plugin for MythTV"
depends=('mythtv' 'python2-oauth')
cd "$srcdir/mythtv-$pkgver/$pkgbase/mythnetvision"
make INSTALL_ROOT="$pkgdir" install
}
package_mythplugins-mythnews() {
pkgdesc="News checking plugin for MythTV"
depends=('mythtv')
cd "$srcdir/mythtv-$pkgver/$pkgbase/mythnews"
make INSTALL_ROOT="$pkgdir" install
}
package_mythplugins-mythweather() {
pkgdesc="Weather checking plugin for MythTV"
depends=('mythtv' 'perl-date-manip' 'perl-json' 'perl-soap-lite'
'perl-xml-sax' 'perl-xml-simple' 'perl-xml-xpath' 'perl-image-size'
'perl-datetime-format-iso8601')
cd "$srcdir/mythtv-$pkgver/$pkgbase/mythweather"
make INSTALL_ROOT="$pkgdir" install
}
package_mythplugins-mythweb() {
pkgdesc="Web interface for the MythTV scheduler"
depends=('mythtv')
optdepends=('lighttpd'
'php-apache')
install='mythplugins-mythweb.install'
mkdir -p "$pkgdir/var/lib/mythtv/mythweb"/{image_cache,php_sessions}
cp -R "$srcdir/mythweb-$pkgver"/* "$pkgdir/var/lib/mythtv/mythweb"
chown -R http:http "$pkgdir/var/lib/mythtv/mythweb"
chmod g+rw "$pkgdir/var/lib/mythtv/mythweb"/{image_cache,php_sessions}
}
package_mythplugins-mythzoneminder() {
pkgdesc="View CCTV footage from zoneminder in MythTV"
depends=('mythtv')
install='mythplugins-mythzoneminder.install'
cd "$srcdir/mythtv-$pkgver/$pkgbase/mythzoneminder"
make INSTALL_ROOT="$pkgdir" install
}
|
