blob: e748b77b3d18d3973cb753f510ccfe076ecff71c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# $Id: PKGBUILD 101573 2013-11-28 01:30:36Z faidoc $
# Maintainer: Alexandre Filgueira <alexfilgueira@cinnarch.com>
# Contributor: Ner0
pkgname=nemo
pkgver=2.0.8
pkgrel=1
pkgdesc="Cinnamon file manager (Nautilus fork)"
arch=('i686' 'x86_64' 'mips64el')
url="https://github.com/linuxmint/nemo"
license=('GPL')
depends=('libexif' 'gvfs' 'dconf' 'desktop-file-utils' 'exempi' 'python2'
'cinnamon-desktop' 'gnome-icon-theme' 'libnotify' 'libtracker-sparql' 'libxml2'
'cinnamon-translations')
makedepends=('gtk-doc' 'gobject-introspection' 'intltool' 'gnome-common')
options=('!emptydirs')
install=nemo.install
source=("$pkgname-$pkgver.tar.gz::https://github.com/linuxmint/nemo/tarball/$pkgver")
sha256sums=('6a40868e46fd2ed6c27e694e76c160996d16e2d27681bf5126e6b0e647c24033')
prepare() {
cd linuxmint-nemo-*
# Python2 fix
sed -i 's/bin\/python/bin\/python2/g' files/usr/share/nemo/actions/myaction.py
# Fix build
sed -i '/AC_SUBST(DISABLE_DEPRECATED_CFLAGS)/d' configure.in
# Rename 'Files' app name to avoid having the same as nautilus
sed -i 's/^Name\(.*\)=.*/Name\1=Nemo/' data/nemo.desktop.in.in
}
build() {
cd linuxmint-nemo-*
./autogen.sh --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --disable-static \
--libexecdir=/usr/lib/nemo \
--disable-update-mimedb \
--disable-packagekit \
--disable-gtk-doc-html \
--disable-schemas-compile
make
}
package() {
cd linuxmint-nemo-*
make DESTDIR="$pkgdir/" install
}
|
