blob: 738d4a39540f5b8eb4c6afdfe55e954bcb00313e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# $Id: PKGBUILD 88884 2013-04-24 15:09:27Z bpiotrowski $
# Maintainer: Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: James Campos <james.r.campos@gmail.com>
# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
# Contributor: Dongsheng Cai <dongsheng at moodle dot com>
# Contributor: Masutu Subric <masutu.arch at googlemail dot com>
# Contributor: TIanyi Cui <tianyicui@gmail.com>
pkgname=nodejs
pkgver=0.10.5
pkgrel=1
pkgdesc='Evented I/O for V8 javascript'
arch=('i686' 'x86_64')
url='http://nodejs.org/'
license=('MIT')
depends=('openssl' 'python2')
checkdepends=('curl')
options=('!emptydirs')
source=(http://nodejs.org/dist/v${pkgver}/node-v${pkgver}.tar.gz)
sha256sums=('1c22bd15cb13b1109610ee256699300ec6999b335f3bc85dc3c0312ec9312cfd')
build() {
cd node-v${pkgver}
msg 'Fixing for python2 name'
find -type f -exec sed \
-e 's_^#!/usr/bin/env python$_&2_' \
-e 's_^\(#!/usr/bin/python2\).[45]$_\1_' \
-e 's_^#!/usr/bin/python$_&2_' \
-e "s_'python'_'python2'_" -i {} \;
find test/ -type f -exec sed 's_python _python2 _' -i {} \;
export PYTHON=python2
./configure \
--prefix=/usr \
--shared-openssl
make
}
check() {
cd node-v${pkgver}
make test || true
}
package() {
cd node-v${pkgver}
make DESTDIR="$pkgdir" install
# install docs as per user request
install -d "$pkgdir"/usr/share/doc/nodejs
cp -r doc/api/*.html \
"$pkgdir"/usr/share/doc/nodejs
install -D -m644 LICENSE \
"$pkgdir"/usr/share/licenses/nodejs/LICENSE
}
# vim:set ts=2 sw=2 et:
|
