blob: ec3def46cf6b2e2db8a063f80f4ac73d00b55891 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Thomas Dziedzic < gostrc at gmail >
# Contributor: James Campos <james.r.campos@gmail.com>
# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
# Contributor: Dongsheng Cai <dongsheng at moodle dot com>
# Contributor: Masutu Subric <masutu.arch at googlemail dot com>
# Contributor: TIanyi Cui <tianyicui@gmail.com>
pkgname=nodejs
pkgver=0.6.10
pkgrel=1
pkgdesc='Evented I/O for V8 javascript'
arch=('i686' 'x86_64')
url='http://nodejs.org/'
license=('MIT')
depends=('python2')
checkdepends=('curl') # curl used for check()
optdepends=('openssl: TLS support')
options=('!emptydirs')
source=("http://nodejs.org/dist/v${pkgver}/node-v${pkgver}.tar.gz")
md5sums=('8a74fd5d48c2c7c64abc60b2b8f3fbc7')
build() {
cd node-v${pkgver}
msg 'fixing for python2 name'
find -type f -exec sed -e 's_^#!/usr/bin/env python$_&2_' -e 's_^\(#!/usr/bin/python2\).[45]$_\1_' -e 's_^#!/usr/bin/python$_&2_' -e "s_'python'_'python2'_" -i {} \;
find test -type f -exec sed -e "s|python |python2 |" -i {} \;
sed -i "s|cmd_R = 'python |cmd_R = 'python2 |" wscript
sed -i "s|python |python2 |" Makefile
find test -type f -exec sed -e 's/python/&2/' -i {} \;
sed -i "s/python/&2/" configure
export PYTHON=python2
./configure \
--prefix=/usr
make
}
check() {
cd node-v${pkgver}
# test failures in 0.6 are known
make test || true
}
package() {
cd node-v${pkgver}
make DESTDIR=${pkgdir} install
# install docs as per user request
install -d ${pkgdir}/usr/share/doc/nodejs
cp -r doc/api/api/* \
${pkgdir}/usr/share/doc/nodejs
install -D -m644 LICENSE \
${pkgdir}/usr/share/licenses/nodejs/LICENSE
}
# vim:set ts=2 sw=2 et:
|
