blob: 36c2d8574e4668d9330196b363f955af3bad3a56 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# $Id: PKGBUILD 92939 2013-06-19 19:43:24Z bpiotrowski $
# Maintainer: Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: James Campos <james.r.campos@gmail.com>
# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
# Contributor: Dongsheng Cai <dongsheng at moodle dot com>
# Contributor: Masutu Subric <masutu.arch at googlemail dot com>
# Contributor: TIanyi Cui <tianyicui@gmail.com>
pkgname=nodejs
pkgver=0.10.12
pkgrel=1
pkgdesc='Evented I/O for V8 javascript'
arch=('i686' 'x86_64')
url='http://nodejs.org/'
license=('MIT')
depends=('openssl')
makedepends=('python2')
checkdepends=('curl')
options=('!emptydirs')
source=(http://nodejs.org/dist/v$pkgver/node-v$pkgver.tar.gz)
sha256sums=('7339a7c333454a567a41c900b6ef2f6c89e8c778062c173beb029611b29496b6')
prepare() {
cd node-v$pkgver
msg 'Fixing for python2 name'
find -type f -exec sed \
-e 's_^#!/usr/bin/env python$_&2_' \
-e 's_^\(#!/usr/bin/python2\).[45]$_\1_' \
-e 's_^#!/usr/bin/python$_&2_' \
-e "s_'python'_'python2'_" -i {} \;
find test/ -type f -exec sed 's_python _python2 _' -i {} \;
}
build() {
cd node-v$pkgver
export PYTHON=python2
./configure \
--prefix=/usr \
--shared-openssl
make
}
check() {
cd node-v$pkgver
make test || true
}
package() {
cd node-v$pkgver
make DESTDIR="$pkgdir" install
# install docs as per user request
install -d "$pkgdir"/usr/share/doc/nodejs
cp -r doc/api/{*.html,assets} \
"$pkgdir"/usr/share/doc/nodejs
install -D -m644 LICENSE \
"$pkgdir"/usr/share/licenses/nodejs/LICENSE
}
# vim:set ts=2 sw=2 et:
|
