blob: cf9d0322e7fc25b9dc19e998636719cdd06d4049 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 100223 2013-11-02 00:00:56Z bisson $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Kaiting Chen <kaitocracy@gmail.com>
# Contributor: Roberto Alsina <ralsina@kde.org>
pkgname=nsd
pkgver=4.0.0
pkgrel=2
pkgdesc='Authoritative only, high performance and simple DNS server'
url='http://www.nlnetlabs.nl/nsd/'
license=('BSD')
arch=('i686' 'x86_64' 'mips64el')
depends=('openssl' 'libevent')
makedepends=('flex')
source=("http://www.nlnetlabs.nl/downloads/${pkgname}/${pkgname}-${pkgver}.tar.gz"
'tmpfiles.d'
'service')
sha1sums=('b3ebd669be8e830f62062d12be55242ca41da369'
'7ad2b8da961a893095eede8963cf8026b13186a1'
'491bf9c6e63644f7d6c81d3b16138f0d87706aa0')
install=install
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure \
--prefix=/ \
--sbindir=/usr/bin \
--datarootdir=/usr/share \
--with-pidfile=/run/nsd/nsd.pid \
--enable-ratelimit
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -Dm644 ../tmpfiles.d "${pkgdir}"/usr/lib/tmpfiles.d/nsd.conf
install -Dm644 ../service "${pkgdir}"/usr/lib/systemd/system/nsd.service
rmdir "${pkgdir}"/{tmp,run/{nsd,}}
rm doc/differences.pdf
install -d "${pkgdir}"/usr/share/{doc,licenses}/"${pkgname}"
install -m644 doc/* "${pkgdir}"/usr/share/doc/"${pkgname}"
ln -s ../../doc/"${pkgname}"/LICENSE "${pkgdir}"/usr/share/licenses/"${pkgname}"/LICENSE
}
|
