blob: bc424cf0ae4b0b4914b1ad61106707aebf6fb192 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# $Id: PKGBUILD 54954 2011-08-29 00:03:04Z bfanella $
# Maintainer: Brad Fanella <bradfanella@archlinux.us>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: tobias <tobias@archlinux.org>
pkgname=openbox
pkgver=3.5.0
pkgrel=4
pkgdesc="A window manager for the X11 windowing system"
arch=('i686' 'x86_64' 'mips64el')
url="http://openbox.org"
license=('GPL')
depends=('startup-notification' 'libxml2' 'libxinerama' 'libxrandr'
'libxcursor' 'pango' 'imlib2')
optdepends=('pyxdg: for the xdg-autostart script')
groups=('lxde')
install=${pkgname}.install
options=('!libtool')
backup=('etc/xdg/openbox/menu.xml' 'etc/xdg/openbox/rc.xml')
source=("http://www.icculus.org/openbox/releases/${pkgname}-${pkgver}.tar.gz"
'which-2.20.patch')
md5sums=('00441b53cf14c03566c8e82643544ff9'
'7ca3b5244bb092d46f5bcf1e2bdf4a18')
build() {
cd "${srcdir}"/${pkgname}-${pkgver}
# FS#11455
patch -p1 -i "${srcdir}"/which-2.20.patch
sed -i 's|/usr/bin/env python|/usr/bin/env python2|' \
data/autostart/openbox-xdg-autostart
./configure --prefix=/usr \
--with-x \
--enable-startup-notification \
--sysconfdir=/etc \
--libexecdir=/usr/lib/openbox
make
}
package() {
cd "${srcdir}"/${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
sed -i "s:startkde:/usr/bin/\0:" \
"${pkgdir}"/usr/share/xsessions/openbox-kde.desktop
sed -i "s:=gnome-session:=/usr/bin/gnome-session:" \
"${pkgdir}"/usr/share/xsessions/openbox-gnome.desktop
}
|
