blob: 7dae25c999f757f1cae621e16a28f6b0dcfe9447 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
|
# $Id: PKGBUILD 90942 2013-05-16 02:47:08Z jconder $
# Maintainer: Jonathan Conder <jonno.conder@gmail.com>
pkgbase='packagekit'
pkgname=('packagekit' 'packagekit-qt2' 'python2-packagekit')
pkgver=0.7.6
pkgrel=10
pkgdesc="A system designed to make installation and updates of packages easier."
arch=('i686' 'x86_64')
url="http://www.packagekit.org"
license=('GPL')
makedepends=('dbus-glib' 'gobject-introspection' 'gtk-doc' 'intltool'
'networkmanager' 'pacman' 'pm-utils' 'polkit' 'python2' 'qt4'
'shared-mime-info' 'sqlite' 'udev')
options=('!libtool')
source=("http://www.packagekit.org/releases/PackageKit-$pkgver.tar.xz"
'adopt.patch'
'alpm.patch'
'libarchive.patch')
sha256sums=('82c0a553075d49add3c4f58e6e93f7f3613938809a4b8e36f46476e86981b45d'
'd0ee8580202a878571dddd470017731299c63e5c5120afe881bb41b9544322b8'
'c7f6da04f5b8f09e6d884ae4f480c064eae10de1d2528bf14d2f55b34e472c23'
'0d3798c8992afdc0930aa271b3e44deb55c046ab4adee25b4ec4c33bcdd950e2')
build() {
cd "$srcdir/PackageKit-$pkgver"
sed -i 's@SUBDIRS = test@SUBDIRS =@' 'backends/Makefile.in'
sed -i 's@python @python2 @' 'lib/python/packagekit/Makefile.in'
sed -i 's@bin/python@bin/python2@' 'lib/python/packagekit/'*.py
patch -Np1 -i "$srcdir/adopt.patch"
patch -Np1 -i "$srcdir/alpm.patch"
patch -Np1 -i "$srcdir/libarchive.patch"
sed -i 's@sbin_PROGRAMS@bin_PROGRAMS@' 'contrib/device-rebind/Makefile.am'
export PYTHON=/usr/bin/python2
./autogen.sh --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--libexecdir=/usr/lib/PackageKit \
--enable-strict \
--disable-static \
--disable-gtk-doc \
--disable-tests \
--disable-local \
--disable-browser-plugin \
--disable-gstreamer-plugin \
--disable-gtk-module \
--disable-command-not-found \
--disable-cron \
--disable-debuginfo-install \
--enable-pm-utils \
--disable-dummy \
--enable-alpm \
--with-default-backend=alpm
make -s CFLAGS='-D_FILE_OFFSET_BITS=64 -O2 -Wno-unused-local-typedefs -Wno-deprecated-declarations -Wno-suggest-attribute=format'
}
package_packagekit() {
backup=('var/lib/PackageKit/transactions.db'
'etc/PackageKit/alpm.d/pacman.conf'
'etc/PackageKit/alpm.d/repos.list')
depends=('dbus-glib' 'pacman>=4.1.0' 'pacman<4.2.0' 'polkit'
'shared-mime-info' 'sqlite' 'udev')
optdepends=('networkmanager')
install='packagekit.install'
cd "$srcdir/PackageKit-$pkgver"
make DESTDIR="$pkgdir" install
rm -rf "$pkgdir/usr/include/PackageKit/packagekit-qt"*
rm -rf "$pkgdir/usr/lib/libpackagekit-qt"*
rm -rf "$pkgdir/usr/lib/pkgconfig/packagekit-qt"*
rm -rf "$pkgdir/usr/lib/cmake"
rm -rf "$pkgdir/usr/lib/python"*
rm -rf "$pkgdir/usr/share/PackageKit/website"
mkdir -p "$pkgdir/usr/share/bash-completion/completions"
mv "$pkgdir/etc/bash_completion.d/pk-completion.bash" \
"$pkgdir/usr/share/bash-completion/completions/pkcon"
rmdir "$pkgdir/etc/bash_completion.d"
touch "$pkgdir/var/log/PackageKit"
}
package_packagekit-qt2() {
depends=('packagekit' 'qt4')
pkgdesc=('Qt bindings for PackageKit')
cd "$srcdir/PackageKit-$pkgver/lib/packagekit-qt2"
make DESTDIR="$pkgdir" install
}
package_python2-packagekit() {
depends=('packagekit' 'python2')
pkgdesc=('Python bindings for PackageKit')
conflicts=('packagekit-python')
replaces=('packagekit-python')
cd "$srcdir/PackageKit-$pkgver/lib/python"
make DESTDIR="$pkgdir" install
}
|
