blob: 8cf2f8700620ef48ee483762873bee1a837257b0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# $Id: PKGBUILD 57784 2011-11-02 15:50:11Z foutrelis $
# Contributor: Vasco Costa <vasco dot costa at geekslot dot com>
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
pkgname=pbzip2
pkgver=1.1.6
pkgrel=1
pkgdesc="Parallel implementation of the bzip2 block-sorting file compressor"
arch=(i686 x86_64 'mips64el')
url="http://compression.ca/pbzip2/"
license=('BSD')
depends=('bzip2' 'gcc-libs')
source=(http://compression.ca/$pkgname/$pkgname-$pkgver.tar.gz)
sha256sums=('86bd6d58e5a6c13cf8c709620ebfe186fca423c2724225bb30431fa7a453aee2')
build() {
cd "$srcdir/$pkgname-$pkgver"
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make PREFIX="$pkgdir/usr" install
# Fix location of man pages
install -d "$pkgdir/usr/share"
mv "$pkgdir/usr/man" "$pkgdir/usr/share"
# Symlinks for useful shortcuts
ln -sf pbzip2 "$pkgdir/usr/bin/pbunzip2"
ln -sf pbzip2 "$pkgdir/usr/bin/pbzcat"
# License
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
# vim:set ts=2 sw=2 et:
|
