blob: 3ba501820c714decf99a0fdfad5f6659782e665e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# $Id: PKGBUILD 83116 2013-01-27 15:26:55Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Kevin Mihelich <kevin@archlinuxarm.org>
pkgname=pdns
pkgver=3.2
pkgrel=1
pkgdesc='Modern, advanced and high performance authoritative-only nameserver'
arch=('x86_64' 'i686')
url='http://www.powerdns.com/'
license=('GPL')
depends=('gcc-libs' 'zlib' 'postgresql-libs' 'libmysqlclient' 'sqlite' 'libldap' 'lua51' 'boost-libs')
makedepends=('boost')
provides=('pdns-ldap' 'pdns-mysql' 'pdns-sqlite' 'pdns-pgsql')
replaces=('pdns-ldap' 'pdns-mysql' 'pdns-sqlite' 'pdns-pgsql')
conflicts=('pdns-ldap' 'pdns-mysql' 'pdns-sqlite' 'pdns-pgsql')
install=pdns.install
options=('!makeflags' '!libtool')
backup=('etc/powerdns/pdns.conf')
source=("http://downloads.powerdns.com/releases/$pkgname-$pkgver.tar.gz"
'pdns.service'
'pdns.rc'
'pdns.conf')
sha256sums=('d1895aba065446dc68e5d7cc792d5303626c71759f61a455531ed65d59c06572'
'2a60c4407bcfe19026ae77d3e3b7b477d5a0c6323c0bc78892e9d907003b442a'
'0457ffa2baa40518a03393e4f76964d9452c16aebbcb925582814f88367d62c2'
'91c8889f41fe9d6bc9478c3ad53a10f6725e36e10f05e8e9257f9d35c9e2bab6')
build() {
cd "$srcdir/$pkgname-$pkgver"
touch AUTHORS NEWS
./configure --prefix=/usr \
--sysconfdir=/etc/powerdns \
--libexecdir=/usr/lib \
--libdir=/usr/lib/powerdns \
--mandir=/usr/share/man \
--with-modules="" \
--with-dynmodules="ldap pipe gmysql gpgsql gsqlite3 geo" \
--disable-recursor \
--disable-static
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -m755 -d "$pkgdir/etc/rc.d"
rm "$pkgdir/etc/powerdns/pdns.conf-dist"
install -m644 "$srcdir/pdns.conf" "$pkgdir/etc/powerdns/"
install -m755 "$srcdir/pdns.rc" "$pkgdir/etc/rc.d/pdns"
install -Dm644 "$srcdir/pdns.service" \
"$pkgdir/usr/lib/systemd/system/pdns.service"
}
# vim:set ts=2 sw=2 et:
|
