blob: 9e679b81b59918f5e6b78de7a3df15e18bd81870 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# $Id: PKGBUILD 90788 2013-05-13 22:34:43Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Kevin Mihelich <kevin@archlinuxarm.org>
pkgname=pdns
pkgver=3.2
pkgrel=7
pkgdesc='Modern, advanced and high performance authoritative-only nameserver'
arch=('x86_64' 'i686' 'mips64el')
url='http://www.powerdns.com/'
license=('GPL')
depends=('boost-libs' 'gcc-libs' 'postgresql-libs' 'libmariadbclient' 'sqlite' 'libldap' 'lua51')
makedepends=('boost')
provides=('pdns-ldap' 'pdns-mysql' 'pdns-sqlite' 'pdns-pgsql')
replaces=('pdns-ldap' 'pdns-mysql' 'pdns-sqlite' 'pdns-pgsql')
conflicts=('pdns-ldap' 'pdns-mysql' 'pdns-sqlite' 'pdns-pgsql')
install="$pkgname.install"
options=('!makeflags' '!libtool')
backup=('etc/powerdns/pdns.conf')
source=("http://downloads.powerdns.com/releases/$pkgname-$pkgver.tar.gz"
'pdns.service'
'pdns.conf')
sha256sums=('d1895aba065446dc68e5d7cc792d5303626c71759f61a455531ed65d59c06572'
'b2358a5951ac944feee15ac03d42ffe9c2a72fa6f57746f77ef8997d54a82040'
'a1afcccb0d2fb6a6f7a5960de95f8d38ce1ac75ac5e3dcecf09e49f0de10166e')
prepare() {
cd "$srcdir/$pkgname-$pkgver"
touch AUTHORS NEWS
}
build() {
cd "$srcdir/$pkgname-$pkgver"
./configure \
--prefix=/usr \
--sysconfdir=/etc/powerdns \
--libexecdir=/usr/lib \
--libdir=/usr/lib/powerdns \
--mandir=/usr/share/man \
--with-modules='' \
--with-dynmodules="ldap pipe gmysql gpgsql gsqlite3 geo" \
--disable-recursor \
--disable-static \
--sbindir=/usr/bin \
--bindir=/usr/bin
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -m644 "$srcdir/pdns.conf" "$pkgdir/etc/powerdns/"
install -Dm644 "$srcdir/pdns.service" \
"$pkgdir/usr/lib/systemd/system/pdns.service"
rm "$pkgdir/etc/powerdns/pdns.conf-dist"
}
# vim:set ts=2 sw=2 et:
|
