blob: 05628853f5c9b6522893165eec4fe90e353ec227 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# $Id: PKGBUILD 104973 2014-01-29 04:07:48Z fyan $
# Maintainer: Felix Yan <felixonmars@gmail.com>
# Contributor: grimsock <lord.grimsock at gmail dot com>
# Contributor: Dieter Plaetinck <dieter@plaetinck.be>
# Contributor: Vladimir Chizhov <jagoterr@gmail.com>
# Contributor: Henry Tang <henryykt@gmail.com>
pkgname=phantomjs
pkgver=1.9.7
pkgrel=1
pkgdesc="Headless WebKit with JavaScript API"
url="http://www.phantomjs.org/"
license=('BSD' 'LGPL' 'MIT')
arch=('i686' 'x86_64')
depends=('gstreamer0.10-base' 'fontconfig' 'freetype2' 'gcc-libs')
makedepends=('git')
source=("git+https://github.com/ariya/${pkgname}.git#tag=$pkgver")
build() {
cd $pkgname
# workaround for http://code.google.com/p/phantomjs/issues/detail?id=635
sed -i 's/QMAKE_LFLAGS+=-fuse-ld=gold/#QMAKE_LFLAGS+=-fuse-ld=gold/' src/qt/src/3rdparty/webkit/Source/common.pri
./build.sh --confirm --qt-config "-no-rpath"
}
package() {
install -Dm755 "$srcdir/$pkgname/bin/phantomjs" "$pkgdir/usr/bin/phantomjs"
mkdir -p "$pkgdir/usr/share/$pkgname"
cp -r "$srcdir/$pkgname/examples" "$pkgdir/usr/share/$pkgname"/
install -Dm644 "$srcdir/$pkgname/LICENSE.BSD" "$pkgdir/usr/share/licenses/$pkgname/LICENSE.BSD"
install -Dm644 "$srcdir/$pkgname/third-party.txt" "$pkgdir/usr/share/licenses/$pkgname/third-party.txt"
}
sha512sums=('SKIP')
|
