blob: 44a999465ac8c0a65ab513fac839a77cf4f8f487 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# $Id: PKGBUILD 73687 2012-07-14 05:57:24Z jlichtblau $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Alexander Fehr <pizzapunk gmail com>
# Contributor: William Rea <sillywilly@gmail.com>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
pkgname=pinot
pkgver=1.0
pkgrel=1
pkgdesc='Personal search and metasearch tool'
arch=('i686' 'x86_64')
url='http://code.google.com/p/pinot-search/'
license=('GPL')
depends=('gtkmm3' 'xapian-core' 'libtextcat' 'sqlite' 'libxml++' 'curl' 'gmime' 'dbus-glib' 'shared-mime-info' 'libexif' 'taglib' 'hicolor-icon-theme' 'cairo' 'exiv2')
makedepends=('boost' 'desktop-file-utils')
optdepends=('unzip: ZIP files extraction'
'poppler: PDF to text conversion'
'catdvi: DVI to text conversion'
'djvulibre: DjVu text extraction'
'unrtf: RTF to HTML conversion'
'antiword: MS Word to text conversion'
'catdoc: XLS and PPT to text conversion')
options=('!emptydirs')
install=$pkgname.install
changelog=$pkgname.changelog
source=(http://pinot-search.googlecode.com/files/$pkgname-$pkgver.tar.gz)
sha256sums=('d1f5ac17022014c5a29ba1e6d95fc39bcf254338a4e0bfe84bf16558d219e2e2')
build() {
cd ${srcdir}/$pkgname-$pkgver
sed -i 's|/usr/share/libtextcat/|/usr/share/libtextcat/LM/|' textcat_conf.txt
sed -i 's|/LM/russian.lm|/LM/russian-windows1251.lm|' textcat_conf.txt
sed -i 's|/usr/share/libtextcat/|/usr/share/libtextcat/LM/|' textcat3_conf.txt
sed -i 's|/usr/share/libtextcat/|/usr/share/libtextcat/LM/|' textcat31_conf.txt
sed -i 's|/usr/share/libtextcat/|/usr/share/libtextcat/LM/|' textcat32_conf.txt
sed -i -e "s|.*russian$|/usr/share/libtextcat/LM/russian-iso8859_5.lm russian-iso8859_5\n\
/usr/share/libtextcat/LM/russian-koi8_r.lm russian-koi8_r\n\
/usr/share/libtextcat/LM/russian-windows1251.lm russian-windows1251|" textcat3_conf.txt
./configure --prefix=/usr --sysconfdir=/etc --libexecdir=/usr/lib --enable-gtkmm3=yes
make
}
package() {
cd ${srcdir}/$pkgname-$pkgver
make DESTDIR=${pkgdir} install
}
|
