blob: 7e5759907911b43a135614eedc9c834b73c06f4e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 89527 2013-04-29 18:57:40Z stativ $
# Maintainer: Lukas Jirkovsky <l.jirkovsky@gmail.com>
pkgname=pion
pkgver=5.0.1
pkgrel=1
pkgdesc="A C++ development library for implementing lightweight HTTP interfaces"
url="https://github.com/cloudmeter/pion"
arch=('i686' 'x86_64')
license=('custom:Boost')
depends=('boost-libs' 'openssl' 'log4cpp')
makedepends=('boost')
provides=('pion-net')
conflicts=('pion-net')
replaces=('pion-net')
source=(https://github.com/cloudmeter/pion/archive/$pkgver.zip)
md5sums=('9f8af4f3e600a5b0573fb66132a86528')
build() {
cd "$srcdir/$pkgname-$pkgver"
sh autogen.sh
# override configure bug (forces debug even when nobody asked for it)
sed -i "s/ -ggdb//g" configure
# override Makefile bug
sed -i "/docs:/ s/doxygen-doc//" Makefile.in
./configure --prefix=/usr --disable-doxygen-doc
make
}
check() {
cd "$srcdir/$pkgname-$pkgver"
make -k check
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
# install license
install -D -m0755 COPYING "$pkgdir/usr/share/licenses/$pkgname/Boost"
}
|
