blob: c64c3497617b436babb63b16e0fcfa60db30dec3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# $Id: PKGBUILD 101429 2013-11-25 14:11:30Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Kevin Mihelich <kevin@archlinuxarm.org>
pkgname=powerdns
pkgver=3.3.1
pkgrel=1
pkgdesc='Authoritative DNS server'
arch=('x86_64' 'i686')
url='http://www.powerdns.com/'
license=('GPL')
depends=('boost-libs' 'gcc-libs' 'postgresql-libs' 'libmariadbclient' 'sqlite' 'libldap' 'lua')
makedepends=('boost')
provides=('pdns' 'pdns-ldap' 'pdns-mysql' 'pdns-sqlite' 'pdns-pgsql')
replaces=('pdns' 'pdns-ldap' 'pdns-mysql' 'pdns-sqlite' 'pdns-pgsql')
conflicts=('pdns' 'pdns-ldap' 'pdns-mysql' 'pdns-sqlite' 'pdns-pgsql')
options=('!makeflags')
backup=('etc/powerdns/pdns.conf')
source=("http://downloads.powerdns.com/releases/pdns-$pkgver.tar.gz"
'pdns.service'
'pdns.conf')
sha256sums=('feb566994725e049391e9b862c9437ca545f1bb970143d2387e474a6ff645bf3'
'b2358a5951ac944feee15ac03d42ffe9c2a72fa6f57746f77ef8997d54a82040'
'a1afcccb0d2fb6a6f7a5960de95f8d38ce1ac75ac5e3dcecf09e49f0de10166e')
prepare() {
cd "pdns-$pkgver"
touch AUTHORS NEWS
}
build() {
cd "pdns-$pkgver"
./configure \
--prefix=/usr \
--sysconfdir=/etc/powerdns \
--libexecdir=/usr/lib \
--libdir=/usr/lib/powerdns \
--mandir=/usr/share/man \
--with-modules='' \
--with-dynmodules="ldap pipe gmysql gpgsql gsqlite3 geo" \
--disable-static \
--sbindir=/usr/bin \
--bindir=/usr/bin
make
}
package() {
make -C "pdns-$pkgver" DESTDIR="$pkgdir" install
install -m644 "$srcdir/pdns.conf" "$pkgdir/etc/powerdns/"
install -Dm644 "$srcdir/pdns.service" \
"$pkgdir/usr/lib/systemd/system/pdns.service"
rm -f "$pkgdir/etc/powerdns/pdns.conf-dist"
}
# vim:set ts=2 sw=2 et:
|
