blob: 54f88aece2d4b5ad15274c7ab44979f19e95ea05 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# $Id: PKGBUILD 97800 2013-09-29 19:59:55Z jlichtblau $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: Matthias Ellmer <ellmer.matthias@gmail.com>
# Contributor: Julien Morin <jmorin@cp.dias.ie>
pkgbase=python-basemap
pkgname=('python-basemap' 'python2-basemap' 'python-basemap-common')
pkgver=1.0.6
pkgrel=3
arch=('i686' 'x86_64')
url="http://matplotlib.org/basemap/"
license=('custom')
makedepends=('python2-numpy' 'python-numpy' 'geos' 'shapelib')
source=("http://downloads.sourceforge.net/project/matplotlib/matplotlib-toolkits/basemap-${pkgver}/basemap-${pkgver}.tar.gz")
sha1sums=('76191964c580b3af33c169cb050bb171328298f9')
_py2basever=2.7
_py3basever=3.3
build() {
pushd "${srcdir}"/basemap-${pkgver}
# Remove the bundled libraries and common data
rm -r geos-*
sed -i "s/lib64/lib/g" setup.py
popd
cp -a "${srcdir}"/basemap-${pkgver}{,-python2}
# Python3 Version
cd "${srcdir}"/basemap-${pkgver}
python setup.py config
python setup.py build
# Python2 Version
cd "${srcdir}"/basemap-${pkgver}-python2
python2 setup.py config
python2 setup.py build
}
package_python-basemap() {
pkgdesc="Toolkit for plotting data on map projections"
depends=('python-basemap-common' 'python-matplotlib' 'geos' 'shapelib' 'python-numpy' 'python-httplib2')
optdepends=('python-imaging: Python Imaging Library is only needed for bluemarble and warpimage methods.')
cd "${srcdir}"/basemap-${pkgver}
python setup.py install -O1 --skip-build --root="${pkgdir}" --prefix=/usr
# Conflict with files from python-matplotlib
rm "${pkgdir}"/usr/lib/python${_py3basever}/site-packages/mpl_toolkits/__init__.py
rm "${pkgdir}"/usr/lib/python${_py3basever}/site-packages/mpl_toolkits/__pycache__/__init__.cpython-33.{pyc,pyo}
rm -fr "${pkgdir}"/usr/lib/python${_py3basever}/site-packages/mpl_toolkits/basemap/data
ln -sf /usr/share/basemap/data "${pkgdir}"/usr/lib/python${_py3basever}/site-packages/mpl_toolkits/basemap/data
}
package_python2-basemap() {
pkgdesc="Toolkit for plotting data on map projections"
depends=('python-basemap-common' 'python2-matplotlib' 'geos' 'shapelib' 'python2-numpy' 'python2-httplib2')
optdepends=('python2-imaging: Python Imaging Library is only needed for bluemarble and warpimage methods.')
cd "${srcdir}"/basemap-${pkgver}-python2
python2 setup.py install -O1 --skip-build --root="${pkgdir}" --prefix=/usr
# Conflict with files from python2-matplotlib
rm "${pkgdir}"/usr/lib/python${_py2basever}/site-packages/mpl_toolkits/__init__.{py,pyc,pyo}
rm -fr "${pkgdir}"/usr/lib/python${_py2basever}/site-packages/mpl_toolkits/basemap/data
ln -sf /usr/share/basemap/data "${pkgdir}"/usr/lib/python${_py2basever}/site-packages/mpl_toolkits/basemap/data
}
package_python-basemap-common() {
pkgdesc="Data files for python-basemap"
cd "${srcdir}"/basemap-${pkgver}
install -dm755 "${pkgdir}"/usr/share/basemap
cp -a lib/mpl_toolkits/basemap/data/ "${pkgdir}"/usr/share/basemap/
install -dm755 "${pkgdir}"/usr/share/licenses/${pkgbase}
install -m644 LICENSE_{data,pyshp,proj4} README "${pkgdir}"/usr/share/licenses/${pkgbase}/
}
|
