blob: c8d884ee865596ac3a3f47f5531a8f62f2f721a0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# $Id: PKGBUILD 104927 2014-01-28 11:43:36Z aginiewicz $
# Maintainer: Andrzej Giniewicz <gginiu@gmail.com>
# Contributor: Sebastien Binet <binet@lblbox>
pkgbase=python-numexpr
pkgname=('python2-numexpr' 'python-numexpr')
pkgver=2.3
pkgrel=1
pkgdesc="Fast numerical array expression evaluator for Python, NumPy, PyTables, pandas"
url="https://github.com/pydata/numexpr"
arch=('i686' 'x86_64')
license=('MIT')
makedepends=('python2-setuptools' 'python-setuptools' 'python-numpy' 'python2-numpy')
source=(https://github.com/pydata/numexpr/archive/$pkgver.tar.gz)
md5sums=('fc9b5765c8ceda4a4c2e974e565b98cf')
build() {
cd "$srcdir"
cp -a numexpr-$pkgver numexpr-py2-$pkgver
msg "Building Python2"
cd "$srcdir"/numexpr-py2-$pkgver
python2 setup.py build
msg "Building Python3"
cd "$srcdir"/numexpr-$pkgver
python setup.py build
}
package_python2-numexpr() {
depends=('python2-numpy')
cd "$srcdir"/numexpr-py2-$pkgver
python2 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
sed -i -e "s|#![ ]*/usr/bin/env python$|#!/usr/bin/python2|" \
$(find "${pkgdir}" -name '*.py')
install -Dm644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
package_python-numexpr() {
depends=('python-numpy')
cd "$srcdir"/numexpr-$pkgver
python setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
install -Dm644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
|