blob: 6fd9c3a948d67ddd6bd13adbac9767a3cee0d469 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# $Id: PKGBUILD 90289 2013-05-10 23:21:33Z seblu $
# Maintainer: Sébastien Luttringer
pkgbase=python-psutil
pkgname=('python-psutil' 'python2-psutil')
pkgver=0.7.1
pkgrel=1
arch=('i686' 'x86_64')
url='http://code.google.com/p/psutil/'
license=('custom: BSD')
makedepends=('python' 'python-distribute' 'python2' 'python2-distribute')
source=("https://psutil.googlecode.com/files/psutil-$pkgver.tar.gz")
sha1sums=('9c67e61ce00166d7831a4cdcbd2fe534708681a1')
build() {
cd psutil-$pkgver
python setup.py build --build-lib=build/python
python2 setup.py build --build-lib=build/python2
find build/python2 -type f -exec \
sed -i '1s,^#! \?/usr/bin/\(env \|\)python$,#!/usr/bin/python2,' {} \;
}
package_python-psutil() {
pkgdesc='A cross-platform process and system utilities module for Python'
depends=('glibc' 'python')
cd psutil-$pkgver
python setup.py build --build-lib=build/python \
install --root="$pkgdir" --optimize=1
install -D -m 644 LICENSE "$pkgdir/"usr/share/licenses/$pkgname/LICENSE
}
package_python2-psutil() {
pkgdesc='A cross-platform process and system utilities module for Python2'
depends=('glibc' 'python2')
cd psutil-$pkgver
python2 setup.py build --build-lib=build/python2 \
install --root="$pkgdir" --optimize=1
install -D -m 644 LICENSE "$pkgdir/"usr/share/licenses/$pkgname/LICENSE
}
# vim:set ts=2 sw=2 et:
|
