blob: e84b00014bfe1a1351d1cb07939d24707a468fb3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# $Id: PKGBUILD 66893 2012-02-29 21:54:35Z rvanharen $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Dmitry N. Shilov <stormblast@land.ru>
pkgname=sakura
pkgver=3.0.0
pkgrel=1
pkgdesc="A terminal emulator based on GTK and VTE"
arch=('i686' 'x86_64' 'mips64el')
url="https://launchpad.net/sakura"
license=('GPL')
depends=('vte3' 'libxft' 'desktop-file-utils')
makedepends=('cmake')
source=(http://pleyades.net/david/projects/$pkgname/$pkgname-$pkgver.tar.bz2
"linker.patch")
install=sakura.install
sha1sums=('2ac4024b40074fb048e9b75cd7ea351b1829c5ee'
'781058944c572b840e68a55a0fe86e97c4ac5296')
build() {
cd $srcdir/${pkgname}-${pkgver}
# missing linker
patch -Np1 -i ${srcdir}/linker.patch
# Set default font size a bit smaller
sed -i 's|#define DEFAULT_FONT "Bitstream Vera Sans Mono 14"|#define DEFAULT_FONT "Bitstream Vera Sans Mono 10"|g' src/sakura.c
# build & install
cmake -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=RELEASE .
make
}
package() {
cd $srcdir/${pkgname}-${pkgver}
make DESTDIR=${pkgdir} install
# extract the keybindings from the installed documentation, rest is only relevant during build time
awk '/^Keybindings/{f="'${pkgdir}'/usr/share/doc/'${pkgname}'/KEYBINDINGS"} f{print > f} /^END/' \
${pkgdir}/usr/share/doc/${pkgname}/INSTALL
rm ${pkgdir}/usr/share/doc/${pkgname}/INSTALL
}
|
