blob: 2fe9dfbb9c0f5fd4ade191dc3ea05a7bc2eda838 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# $Id: PKGBUILD 96970 2013-09-09 14:29:18Z mtorromeo $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
pkgname=sshguard
pkgver=1.5
pkgrel=15
pkgdesc="Brute force detector for SSH, Exim, VSFTPD and more. Blocks by ip with iptables"
arch=('i686' 'x86_64')
url="http://www.sshguard.net/"
license=('GPL')
depends=('iptables')
options=(zipman)
install=sshguard.install
source=("http://downloads.sourceforge.net/sourceforge/sshguard/sshguard-$pkgver.tar.bz2"
sshguard.service
sshguard-journalctl)
sha256sums=('b537f8765455fdf8424f87d4bd695e5b675b88e5d164865452137947093e7e19'
'3185cd3ceeee0bbb1f1df54baf025857200f39bd1eb747a59d6f46c562be4a51'
'f7b307fe9dbbe8c18fe91ca751679d62b2a3ade03cfe164e76ca411cfafffca6')
prepare() {
cd "$srcdir/$pkgname-$pkgver"
sed -i 's|^DAYNO.*|DAYNO [0-9]?[1-9]|' src/parser/attack_scanner.l
}
build() {
cd "$srcdir/$pkgname-$pkgver"
./configure --prefix=/usr --sbindir=/usr/bin --with-firewall=iptables
make
}
check() {
cd "$srcdir/$pkgname-$pkgver"
strings src/sshguard | grep -E "^`which iptables`[[:space:]]" >/dev/null
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -Dm0644 "$srcdir/sshguard.service" "$pkgdir/usr/lib/systemd/system/sshguard.service"
install -Dm0755 "$srcdir/sshguard-journalctl" "$pkgdir/usr/lib/systemd/scripts/sshguard-journalctl"
}
|
