blob: cbe4b5422ca2df5d995cad1df3b58ce7768a27a8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# $Id: PKGBUILD 77129 2012-10-05 11:05:03Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Martin Devera <devik@cdi.cz>
pkgname=sysstat
pkgver=10.1.1
pkgrel=2
pkgdesc="a collection of performance monitoring tools (iostat,isag,mpstat,pidstat,sadf,sar)"
arch=('i686' 'x86_64' 'mips64el')
url="http://pagesperso-orange.fr/sebastien.godard/"
license=('GPL')
depends=('lm_sensors')
optdepends=('tk: to use isag'
'gnuplot: to use isag')
options=(zipman)
backup=('etc/conf.d/sysstat'
'etc/conf.d/sysstat.ioconf')
source=(http://pagesperso-orange.fr/sebastien.godard/$pkgname-$pkgver.tar.gz
sysstat
sysstat.service)
md5sums=('8250cdcbc4a959c8a05e4186fbd13d84'
'3ce41ebf7330aba01e70b38658afed1f'
'f447a8081a07a73407b4b04afc027ebc')
build() {
cd $srcdir/$pkgname-$pkgver
conf_dir=/etc/conf.d ./configure --prefix=/usr \
--enable-yesterday \
--mandir=/usr/share/man \
--enable-install-isag \
--disable-man-group
make
}
package() {
cd $srcdir/$pkgname-$pkgver
make DESTDIR=$pkgdir install
install -D -m 744 cron/sysstat.cron.hourly $pkgdir/etc/cron.hourly/sysstat
install -D -m 744 cron/sysstat.cron.daily $pkgdir/etc/cron.daily/sysstat
install -D -m 755 $srcdir/sysstat $pkgdir/etc/rc.d/sysstat
chown -R root:root $pkgdir
install -Dm0644 $srcdir/$pkgname.service $pkgdir/usr/lib/systemd/system/$pkgname.service
}
|
