blob: 227efcbec1f7d2b9089f68878bcd0ed252ac6b3a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 85671 2013-03-04 16:46:31Z tredaelli $
# Maintainer: Timothy Redaelli <timothy.redaelli@gmail.com>
# Contributor: helios
# Contributor: Lothar Gesslein
# Contributor: Dominik George <nik@naturalnet.de>
pkgname=tinc
pkgver=1.0.20
pkgrel=1
pkgdesc="VPN (Virtual Private Network) daemon"
arch=('i686' 'x86_64')
url="http://www.tinc-vpn.org/"
license=('GPL')
depends=('lzo2' 'openssl')
backup=(etc/conf.d/tincd.conf)
install=tinc.install
source=(http://www.tinc-vpn.org/packages/tinc-$pkgver.tar.gz{,.sig}
tincd.rc tincd.conf tincd@.service)
md5sums=('001277e0ccd7ca29f7fa4039774ad611'
'8ad9e8784712bdc1496223c6dbd99ab9'
'64bb53748d9051255f243003f0d511f5'
'7c0276d4812cc5d3cc18142562a3aa82'
'035b0e549b08da55d19a8df5b8306e4d')
build() {
cd "$srcdir/$pkgname-$pkgver"
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir/" install
install -dm755 "$pkgdir"/usr/share/tinc/examples
tar xozvf doc/sample-config.tar.gz -C $pkgdir/usr/share/tinc/examples
find "$pkgdir"/usr/share/tinc/examples -type f -exec chmod 644 {} +
find "$pkgdir"/usr/share/tinc/examples -type d -exec chmod 755 {} +
install -Dm755 "$srcdir/tincd.rc" "$pkgdir/etc/rc.d/tincd"
install -Dm644 "$srcdir/tincd.conf" "$pkgdir/etc/conf.d/tincd.conf"
install -Dm644 "$srcdir/tincd@.service" "$pkgdir/usr/lib/systemd/system/tincd@.service"
}
|
