blob: b8e3ccf85480a345e5d76f51f51977bf387e3617 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# $Id: PKGBUILD 49818 2011-06-21 09:19:30Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Alexander Fehr <pizzapunk gmail com>
pkgname=tracker
pkgver=0.10.18
pkgrel=1
pkgdesc="Powerful object database, tag/metadata database, search tool and indexer"
arch=('i686' 'x86_64')
url="http://www.gnome.org/projects/tracker/"
license=('GPL')
depends=('upower' 'poppler-glib' 'gstreamer0.10-base' 'libgee' 'gnome-desktop' 'libnotify' 'xdg-utils' 'gtkhtml'
'libgsf' 'gnome-panel-bonobo' 'exempi' 'networkmanager')
makedepends=('intltool' 'gnome-panel' 'nautilus' 'evolution' 'totem-plparser' 'icu')
optdepends=('nautilus'
'enca'
'gtkhtml'
'gnome-panel'
'totem-plparser'
'icu'
'taglib'
'giflib')
options=('!libtool')
conflicts=('libtracker')
provides=("libtracker")
install=tracker.install
source=(http://ftp.gnome.org/pub/GNOME/sources/tracker/0.10/tracker-$pkgver.tar.bz2)
md5sums=('571b915d0173d9d5f2e3310ffd02e8e6')
build() {
cd "$srcdir/$pkgname-$pkgver"
# python2 fix
export PYTHON=`which python2`
for file in tests/functional-tests/*.py; do
sed -i 's_#!/usr/bin/env python_#!/usr/bin/env python2_' $file
sed -i 's_#!/usr/bin/python_#!/usr/bin/python2_' $file
done
./configure --prefix=/usr --sysconfdir=/etc --libexecdir=/usr/lib/$pkgname \
--enable-video-extractor=gstreamer --disable-hal \
--disable-miner-evolution
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
}
|
