blob: 55b41757aee51c59030384a42981f978b059b670 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Simone Sclavi 'Ito' <darkhado@gmail.com>
pkgname=turbojpeg
pkgver=1.2.1
pkgrel=1
pkgdesc="turbojpeg library from libjpeg-turbo"
arch=('i686' 'x86_64')
url="http://www.libjpeg-turbo.org/About/TurboJPEG"
license=('GPL' 'custom')
depends=('glibc' 'libjpeg')
makedepends=('nasm')
options=('!libtool')
source=(http://sourceforge.net/projects/libjpeg-turbo/files/$pkgver/libjpeg-turbo-$pkgver.tar.gz)
sha1sums=('a4992e102c6d88146709e8e6ce5896d5d0b5a361')
build() {
cd "$srcdir/libjpeg-turbo-$pkgver"
./configure --prefix=/usr --with-jpeg8 --mandir=/usr/share/man
make
}
check() {
cd "$srcdir/libjpeg-turbo-$pkgver"
make test
}
package() {
cd "$srcdir/libjpeg-turbo-$pkgver"
make DESTDIR="$pkgdir/" install
# only distribute libturbojpeg
rm -rf "$pkgdir"/usr/share
rm "$pkgdir"/usr/include/j*.h
rm "$pkgdir"/usr/lib/libj*
rm "$pkgdir"/usr/bin/{djpeg,rdjpgcom,wrjpgcom,jpegtran,cjpeg}
install -Dm644 README "$pkgdir/usr/share/licenses/$pkgname/README"
install -Dm644 README-turbo.txt "$pkgdir/usr/share/licenses/$pkgname/README-turbo.txt"
}
|
